blob: bb0035b976694466a1aebf0c19c4eb6642cf4e2f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
{
lib,
stdenv,
fetchFromGitHub,
cmake,
nix-update-script,
testers,
validatePkgConfig,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "jansson";
version = "2.14";
outputs = [
"dev"
"out"
];
src = fetchFromGitHub {
owner = "akheron";
repo = "jansson";
rev = "v${finalAttrs.version}";
hash = "sha256-FQgy2+g3AyRVJeniqPQj0KNeHgPdza2pmEIXqSyYry4=";
};
nativeBuildInputs = [
cmake
validatePkgConfig
];
cmakeFlags = [
# networkmanager relies on libjansson.so:
# https://github.com/NixOS/nixpkgs/pull/176302#issuecomment-1150239453
"-DJANSSON_BUILD_SHARED_LIBS=${if stdenv.hostPlatform.isStatic then "OFF" else "ON"}"
];
passthru = {
tests.pkg-config = testers.hasPkgConfigModules { package = finalAttrs.finalPackage; };
updateScript = nix-update-script { };
};
meta = {
description = "C library for encoding, decoding and manipulating JSON data";
homepage = "https://github.com/akheron/jansson";
changelog = "https://github.com/akheron/jansson/raw/${finalAttrs.src.rev}/CHANGES";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ getchoo ];
platforms = lib.platforms.all;
pkgConfigModules = [ "jansson" ];
};
})
|
