1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
{ stdenv
, lib
, fetchzip
, fetchpatch
, rustPlatform
# native build inputs
, pkg-config
, installShellFiles
, makeWrapper
, mandoc
, rustfmt
, file
# build inputs
, openssl
, dbus
, sqlite
# runtime deps
, gpgme
, gnum4
}:
rustPlatform.buildRustPackage rec {
pname = "meli";
version = "0.8.7";
src = fetchzip {
urls = [
"https://git.meli-email.org/meli/meli/archive/v${version}.tar.gz"
"https://codeberg.org/meli/meli/archive/v${version}.tar.gz"
"https://github.com/meli/meli/archive/refs/tags/v${version}.tar.gz"
];
hash = "sha256-2+JIehi2wuWdARbhFPvNPIJ9ucZKWjNSORszEG9lyjw=";
};
cargoHash = "sha256-ZVhUkpiiPKbWcf56cXFgn3Nyr63STHLlD7mpYEetNIY=";
cargoPatches = [
(fetchpatch {
# https://github.com/NixOS/nixpkgs/issues/332957#issuecomment-2278578811
name = "fix-rust-1.80-compat.patch";
url = "https://git.meli-email.org/meli/meli/commit/6b05279a0987315c401516cac8ff0b016a8e02a8.patch";
hash = "sha256-mh8H7wmHMXAe01UTvdY8vJeeLyH6ZFwylNLFFL+4LO0=";
})
];
# Needed to get openssl-sys to use pkg-config
OPENSSL_NO_VENDOR=1;
nativeBuildInputs = [
pkg-config
installShellFiles
makeWrapper
mandoc
(rustfmt.override { asNightly = true; })
];
buildInputs = [
openssl
dbus
sqlite
];
nativeCheckInputs = [
file
gnum4
];
postInstall = ''
installManPage meli/docs/*.{1,5,7}
wrapProgram $out/bin/meli \
--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ gpgme ]} \
--prefix PATH : ${lib.makeBinPath [ gnum4 ]}
'';
preCheck = ''
export HOME=$(mktemp -d)
'';
checkFlags = [
"--skip=conf::tests::test_config_parse" # panicking due to sandbox
"--skip=utils::tests::test_shellexpandtrait_impls" # panicking due to sandbox
"--skip=utils::tests::test_shellexpandtrait" # panicking due to sandbox
];
meta = with lib; {
broken = (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64);
description = "Terminal e-mail client and e-mail client library";
mainProgram = "meli";
homepage = "https://meli.delivery";
license = licenses.gpl3;
maintainers = with maintainers; [ _0x4A6F matthiasbeyer ];
platforms = platforms.linux;
};
}
|
