pkgs/by-name/ne/neovim-qt/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

{ stdenv, libsForQt5, makeWrapper, neovim, neovim-qt-unwrapped }:

let
  unwrapped = neovim-qt-unwrapped;
in
libsForQt5.mkDerivation {
  pname = "neovim-qt";
  version = unwrapped.version;
  buildCommand = if stdenv.isDarwin then ''
    mkdir -p $out/Applications
    cp -r ${unwrapped}/bin/nvim-qt.app $out/Applications

    chmod -R a+w $out/Applications/nvim-qt.app/Contents/MacOS
    wrapProgram $out/Applications/nvim-qt.app/Contents/MacOS/nvim-qt \
      --prefix PATH : ${neovim}/bin
  '' else ''
    makeWrapper ${unwrapped}/bin/nvim-qt $out/bin/nvim-qt \
      --prefix PATH : ${neovim}/bin

    # link .desktop file
    mkdir -p $out/share/pixmaps
    ln -s ${unwrapped}/share/applications $out/share/applications
    ln -s ${unwrapped}/share/icons $out/share/icons
  '';

  preferLocalBuild = true;

  nativeBuildInputs = [
    makeWrapper
  ];

  passthru = {
    inherit unwrapped;
  };

  inherit (unwrapped) meta;
}