pkgs/by-name/ni/nix-top/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

{
  binutils-unwrapped, # strings
  coreutils,
  getent, # /etc/passwd
  fetchFromGitHub,
  findutils,
  lib,
  makeWrapper,
  ncurses, # tput
  ruby,
  stdenv,
}:

# No gems used, so mkDerivation is fine.
let
  additionalPath = lib.makeBinPath [
    getent
    ncurses
    binutils-unwrapped
    coreutils
    findutils
  ];
in
stdenv.mkDerivation rec {
  pname = "nix-top";
  version = "0.3.0";

  src = fetchFromGitHub {
    owner = "jerith666";
    repo = "nix-top";
    rev = "v${version}";
    hash = "sha256-w/TKzbZmMt4CX2KnLwPvR1ydp5NNlp9nNx78jJvhp54=";
  };

  nativeBuildInputs = [ makeWrapper ];

  buildInputs = [ ruby ];

  installPhase =
    ''
      runHook preInstall
      mkdir -p $out/libexec/nix-top
      install -D -m755 ./nix-top $out/bin/nix-top
      wrapProgram $out/bin/nix-top \
        --prefix PATH : "$out/libexec/nix-top:${additionalPath}"
    ''
    + lib.optionalString stdenv.isDarwin ''
      ln -s /bin/stty $out/libexec/nix-top
    ''
    + ''
      runHook postInstall
    '';

  meta = {
    description = "Tracks what nix is building";
    homepage = "https://github.com/jerith666/nix-top";
    license = lib.licenses.mit;
    maintainers = [ lib.maintainers.jerith666 ];
    platforms = lib.platforms.unix;
    mainProgram = "nix-top";
  };
}