1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{
lib,
stdenv,
fetchurl,
libpcap,
pkg-config,
openssl,
lua5_4,
pcre2,
liblinear,
libssh2,
zlib,
withLua ? true,
}:
stdenv.mkDerivation rec {
pname = "nmap";
version = "7.95";
src = fetchurl {
url = "https://nmap.org/dist/nmap-${version}.tar.bz2";
hash = "sha256-4Uq1MOR7Wv2I8ciiusf4nNj+a0eOItJVxbm923ocV3g=";
};
prePatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
substituteInPlace libz/configure \
--replace /usr/bin/libtool ar \
--replace 'AR="libtool"' 'AR="ar"' \
--replace 'ARFLAGS="-o"' 'ARFLAGS="-r"'
'';
configureFlags = [
(if withLua then "--with-liblua=${lua5_4}" else "--without-liblua")
"--without-ndiff"
"--without-zenmap"
];
postInstall = ''
install -m 444 -D nselib/data/passwords.lst $out/share/wordlists/nmap.lst
'';
postFixup = lib.optionalString stdenv.hostPlatform.isDarwin ''
install_name_tool -change liblinear.so.5 ${liblinear.out}/lib/liblinear.5.dylib $out/bin/nmap
'';
makeFlags = lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
"AR=${stdenv.cc.bintools.targetPrefix}ar"
"RANLIB=${stdenv.cc.bintools.targetPrefix}ranlib"
"CC=${stdenv.cc.targetPrefix}gcc"
];
nativeBuildInputs = [ pkg-config ];
buildInputs = [
pcre2
liblinear
libssh2
libpcap
openssl
zlib
];
enableParallelBuilding = true;
doCheck = false; # fails 3 tests, probably needs the net
meta = {
description = "Free and open source utility for network discovery and security auditing";
homepage = "http://www.nmap.org";
license = lib.licenses.gpl2Only;
platforms = lib.platforms.all;
maintainers = with lib.maintainers; [
thoughtpolice
fpletz
];
};
}
|
