1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
|
{ lib
, buildNpmPackage
, gettext
, python3
, fetchFromGitHub
, fetchpatch2
, plugins ? [ ]
, nixosTests
}:
let
python = python3.override {
packageOverrides = final: prev: {
django-bootstrap4 = prev.django-bootstrap4.overridePythonAttrs (oldAttrs: rec {
version = "3.0.0";
src = oldAttrs.src.override {
rev = "v${version}";
hash = "sha256-a8BopUwZjmvxOzBVqs4fTo0SY8sEEloGUw90daYWfz8=";
};
propagatedBuildInputs = with final; [
beautifulsoup4
django
];
# fails with some assertions
doCheck = false;
});
};
};
version = "2024.1.0";
src = fetchFromGitHub {
owner = "pretalx";
repo = "pretalx";
rev = "v${version}";
hash = "sha256-rFOlovybaEZnv5wBx6Dv8bVkP1D+CgYAKRXuNb6hLKQ=";
};
meta = with lib; {
description = "Conference planning tool: CfP, scheduling, speaker management";
mainProgram = "pretalx-manage";
homepage = "https://github.com/pretalx/pretalx";
changelog = "https://docs.pretalx.org/en/latest/changelog.html";
license = licenses.asl20;
maintainers = with maintainers; [ hexa] ++ teams.c3d2.members;
platforms = platforms.linux;
};
frontend = buildNpmPackage {
pname = "pretalx-frontend";
inherit version src;
sourceRoot = "${src.name}/src/pretalx/frontend/schedule-editor";
npmDepsHash = "sha256-B9R3Nn4tURNxzeyLDHscqHxYOQK9AcmDnyNq3k5WQQs=";
npmBuildScript = "build";
inherit meta;
};
in
python.pkgs.buildPythonApplication rec {
pname = "pretalx";
inherit version src;
pyproject = true;
outputs = [
"out"
"static"
];
patches = [
(fetchpatch2 {
# Backport support for Djangorestframework 3.15.x
name = "pretalx-drf-3.15.patch";
url = "https://github.com/pretalx/pretalx/commit/43a0416c6968d64ea57720abdb82f482940b11f8.patch";
hash = "sha256-Iw1xVF7j7c712kwIk1SMbQSF0ixMUZr1BJib3KAb2HY=";
})
];
postPatch = ''
substituteInPlace src/pretalx/common/management/commands/rebuild.py \
--replace 'subprocess.check_call(["npm", "run", "build"], cwd=frontend_dir, env=env)' ""
substituteInPlace src/setup.cfg \
--replace "--cov=./ --cov-report=" ""
'';
nativeBuildInputs = [
gettext
] ++ (with python.pkgs; [
pythonRelaxDepsHook
setuptools
]);
pythonRelaxDeps = [
"celery"
"css-inline"
"cssutils"
"django-compressor"
"django-csp"
"django-filter"
"django-hierarkey"
"djangorestframework"
"markdown"
"pillow"
"python-dateutil"
"reportlab"
"requests"
"rules"
];
propagatedBuildInputs = with python.pkgs; [
beautifulsoup4
bleach
celery
css-inline
csscompressor
cssutils
defusedcsv
django
django-bootstrap4
django-compressor
django-context-decorator
django-countries
django-csp
django-filter
django-formset-js-improved
django-formtools
django-hierarkey
django-i18nfield
django-libsass
django-scopes
djangorestframework
libsass
markdown
pillow
publicsuffixlist
python-dateutil
qrcode
reportlab
requests
rules
urlman
vobject
whitenoise
zxcvbn
] ++ beautifulsoup4.optional-dependencies.lxml ++ plugins;
passthru.optional-dependencies = {
mysql = with python.pkgs; [
mysqlclient
];
postgres = with python.pkgs; [
psycopg2
];
redis = with python.pkgs; [
redis
];
};
postBuild = ''
rm -r ./src/pretalx/frontend/schedule-editor
ln -s ${frontend}/lib/node_modules/@pretalx/schedule-editor ./src/pretalx/frontend/schedule-editor
# Generate all static files, see https://docs.pretalx.org/administrator/commands.html#python-m-pretalx-rebuild
PYTHONPATH=$PYTHONPATH:./src python -m pretalx rebuild
'';
postInstall = ''
mkdir -p $out/bin
cp ./src/manage.py $out/bin/pretalx-manage
# The processed source files are in the static output, except for fonts, which are duplicated.
# See <https://github.com/pretalx/pretalx/issues/1585> for more details.
find $out/${python.sitePackages}/pretalx/static \
-mindepth 1 \
-not -path "$out/${python.sitePackages}/pretalx/static/fonts*" \
-delete
# Copy generated static files into dedicated output
mkdir -p $static
cp -r ./src/static.dist/** $static/
# Copy frontend files
ln -s ${frontend}/lib/node_modules/@pretalx/schedule-editor/dist/* $static
'';
preCheck = ''
export PRETALX_CONFIG_FILE="$src/src/tests/ci_sqlite.cfg"
cd src
'';
nativeCheckInputs = with python.pkgs; [
faker
freezegun
jsonschema
pytest-django
pytest-mock
pytest-xdist
pytestCheckHook
responses
] ++ lib.flatten (builtins.attrValues passthru.optional-dependencies);
disabledTests = [
# tries to run npm run i18n:extract
"test_common_custom_makemessages_does_not_blow_up"
# Expected to perform X queries or less but Y were done
"test_can_see_schedule"
"test_schedule_export_public"
"test_schedule_frab_json_export"
"test_schedule_frab_xcal_export"
"test_schedule_frab_xml_export"
"test_schedule_frab_xml_export_control_char"
"test_schedule_page_text_list"
"test_schedule_page_text_table"
"test_schedule_page_text_wrong_format"
"test_versioned_schedule_page"
];
passthru = {
inherit python;
tests = {
inherit (nixosTests) pretalx;
};
plugins = lib.recurseIntoAttrs (
lib.packagesFromDirectoryRecursive {
inherit (python.pkgs) callPackage;
directory = ./plugins;
}
);
};
inherit meta;
}
|