blob: 5fb77607ed47d1be1f79d26d53b4b6b232cf29ed (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{ lib, fetchFromGitHub, buildDotnetModule, dotnetCorePackages, stdenvNoCC, testers, roslyn-ls, jq }:
let
pname = "roslyn-ls";
dotnet-sdk = with dotnetCorePackages; combinePackages [ sdk_6_0 sdk_7_0 sdk_8_0 sdk_9_0 ];
# need sdk on runtime as well
dotnet-runtime = dotnetCorePackages.sdk_9_0;
project = "Microsoft.CodeAnalysis.LanguageServer";
in
buildDotnetModule rec {
inherit pname dotnet-sdk dotnet-runtime;
vsVersion = "2.45.17";
src = fetchFromGitHub {
owner = "dotnet";
repo = "roslyn";
rev = "VSCode-CSharp-${vsVersion}";
hash = "sha256-5u+5UkcWn5XKxhbAbZeUBWBAI4B1nuZFP4qDF4cHerU=";
};
# versioned independently from vscode-csharp
# "roslyn" in here:
# https://github.com/dotnet/vscode-csharp/blob/main/package.json
version = "4.12.0-2.24422.6";
projectFile = "src/LanguageServer/${project}/${project}.csproj";
useDotnetFromEnv = true;
nugetDeps = ./deps.nix;
nativeBuildInputs = [ jq ];
postPatch = ''
# Upstream uses rollForward = latestPatch, which pins to an *exact* .NET SDK version.
jq '.sdk.rollForward = "latestMinor"' < global.json > global.json.tmp
mv global.json.tmp global.json
substituteInPlace $dotnetProjectFiles \
--replace-fail \
'>win-x64;win-arm64;linux-x64;linux-arm64;linux-musl-x64;linux-musl-arm64;osx-x64;osx-arm64</RuntimeIdentifiers>' \
'>linux-x64;linux-arm64;osx-x64;osx-arm64</RuntimeIdentifiers>'
'';
dotnetFlags = [
# this removes the Microsoft.WindowsDesktop.App.Ref dependency
"-p:EnableWindowsTargeting=false"
# see this comment: https://github.com/NixOS/nixpkgs/pull/318497#issuecomment-2256096471
# we can remove below line after https://github.com/dotnet/roslyn/issues/73439 is fixed
"-p:UsingToolMicrosoftNetCompilers=false"
];
# two problems solved here:
# 1. --no-build removed -> BuildHost project within roslyn is running Build target during publish
# 2. missing crossgen2 7.* in local nuget directory when PublishReadyToRun=true
# the latter should be fixable here but unsure how
installPhase =
let
rid = dotnetCorePackages.systemToDotnetRid stdenvNoCC.targetPlatform.system;
in
''
runHook preInstall
env dotnet publish $dotnetProjectFiles \
-p:ContinuousIntegrationBuild=true \
-p:Deterministic=true \
-p:InformationalVersion=$version \
-p:UseAppHost=true \
-p:PublishTrimmed=false \
-p:PublishReadyToRun=false \
--configuration Release \
--no-self-contained \
--output "$out/lib/$pname" \
--runtime ${rid} \
''${dotnetInstallFlags[@]} \
''${dotnetFlags[@]}
runHook postInstall
'';
passthru = {
tests.version = testers.testVersion { package = roslyn-ls; };
updateScript = ./update.sh;
};
meta = {
homepage = "https://github.com/dotnet/vscode-csharp";
description = "Language server behind C# Dev Kit for Visual Studio Code";
changelog = "https://github.com/dotnet/vscode-csharp/releases/tag/v${vsVersion}";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ konradmalik ];
mainProgram = "Microsoft.CodeAnalysis.LanguageServer";
};
}
|
