1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
{ lib
, stdenv
, fetchurl
, fetchFromGitHub
, makeWrapper
, meson
, ninja
, pkg-config
, runtimeShell
, installShellFiles
, android-tools
, ffmpeg
, libusb1
, SDL2
}:
let
version = "2.7";
prebuilt_server = fetchurl {
name = "scrcpy-server";
inherit version;
url = "https://github.com/Genymobile/scrcpy/releases/download/v${version}/scrcpy-server-v${version}";
hash = "sha256-ojxWWfNsJg8QXAItJ7yz6v/6JgcOe6qe2mbQE3ehrbo=";
};
in
stdenv.mkDerivation rec {
pname = "scrcpy";
inherit version;
src = fetchFromGitHub {
owner = "Genymobile";
repo = "scrcpy";
rev = "refs/tags/v${version}";
hash = "sha256-OBMm/GkiIdZaJd9X62vY4M6FVKiHTBwqRtH220bYej4=";
};
# display.c: When run without a hardware accelerator, this allows the command to continue working rather than failing unexpectedly.
# This can happen when running on non-NixOS because then scrcpy seems to have a hard time using the host OpenGL-supporting hardware.
# It would be better to fix the OpenGL problem, but that seems much more intrusive.
postPatch = ''
substituteInPlace app/src/display.c \
--replace "SDL_RENDERER_ACCELERATED" "SDL_RENDERER_ACCELERATED || SDL_RENDERER_SOFTWARE"
'';
nativeBuildInputs = [ makeWrapper meson ninja pkg-config installShellFiles ];
buildInputs = [ ffmpeg SDL2 libusb1 ];
# Manually install the server jar to prevent Meson from "fixing" it
preConfigure = ''
echo -n > server/meson.build
'';
postInstall = ''
mkdir -p "$out/share/scrcpy"
ln -s "${prebuilt_server}" "$out/share/scrcpy/scrcpy-server"
# runtime dep on `adb` to push the server
wrapProgram "$out/bin/scrcpy" --prefix PATH : "${android-tools}/bin"
'' + lib.optionalString stdenv.isLinux ''
substituteInPlace $out/share/applications/scrcpy-console.desktop \
--replace "/bin/bash" "${runtimeShell}"
'';
meta = {
description = "Display and control Android devices over USB or TCP/IP";
homepage = "https://github.com/Genymobile/scrcpy";
changelog = "https://github.com/Genymobile/scrcpy/releases/tag/v${version}";
sourceProvenance = with lib.sourceTypes; [
fromSource
binaryBytecode # server
];
license = lib.licenses.asl20;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ deltaevo ryand56 ];
mainProgram = "scrcpy";
};
}
|
