blob: cdf40eacedae4c1666fa1bdcc2d315a80391dcb7 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
{ lib
, fetchFromGitHub
, makeWrapper
, python3
, unstableGitUpdater
, poetry
}:
python3.pkgs.buildPythonApplication rec {
pname = "sherlock";
version = "0-unstable-2024-06-09";
format = "pyproject";
src = fetchFromGitHub {
owner = "sherlock-project";
repo = "sherlock";
rev = "d678908c00f16c7f6c44efc0357cef713fa96739";
hash = "sha256-XAXDqbdHQta9OiupbPmmyp3TK1VLtDQ7CadsOei/6rs=";
};
patches = [
# Avoid hardcoding sherlock
./fix-sherlock-bin-test.patch
];
postPatch = ''
substituteInPlace tests/sherlock_interactives.py \
--replace @sherlockBin@ "$out/bin/sherlock"
'';
nativeBuildInputs = [ makeWrapper ];
propagatedBuildInputs = with python3.pkgs; [
certifi
colorama
pandas
pysocks
requests
requests-futures
stem
torrequest
];
installPhase = ''
runHook preInstall
mkdir -p $out/bin $out/share
cp -R ./sherlock $out/share
runHook postInstall
'';
postFixup = ''
makeWrapper ${python3.interpreter} $out/bin/sherlock \
--add-flags "-m" \
--add-flags "sherlock" \
--prefix PYTHONPATH : "$PYTHONPATH:$out/share"
'';
nativeCheckInputs = with python3.pkgs; [
pytestCheckHook
poetry
poetry-core
jsonschema
openpyxl
stem
pythonRelaxDepsHook
];
pythonRelaxDeps = [
"stem"
];
pytestFlagsArray = [
"-m"
"'not online'"
];
passthru.updateScript = unstableGitUpdater {
hardcodeZeroVersion = true;
};
meta = with lib; {
homepage = "https://sherlock-project.github.io/";
description = "Hunt down social media accounts by username across social networks";
license = licenses.mit;
mainProgram = "sherlock";
maintainers = with maintainers; [ applePrincess ];
};
}
|