blob: 37a9849b2830cbdd8736f41de1bc20f99e695923 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{
lib,
overrideSDK,
stdenv,
darwin,
fetchFromGitHub,
testers,
nix-update-script,
}:
let
inherit (stdenv.hostPlatform) system;
inherit (darwin.apple_sdk_11_0.frameworks)
AppKit
Carbon
CoreAudio
CoreWLAN
CoreVideo
DisplayServices
IOKit
MediaRemote
SkyLight
;
target =
{
"aarch64-darwin" = "arm64";
"x86_64-darwin" = "x86";
}
.${system} or (throw "Unsupported system: ${system}");
stdenv' = if stdenv.isDarwin then overrideSDK stdenv "11.0" else stdenv;
in
stdenv'.mkDerivation (finalAttrs: {
pname = "sketchybar";
version = "2.21.0";
src = fetchFromGitHub {
owner = "FelixKratz";
repo = "SketchyBar";
rev = "v${finalAttrs.version}";
hash = "sha256-hTfQQjx6ai83zYFfccsz/KaoZUIj5Dfz4ENe59gS02E=";
};
buildInputs = [
AppKit
Carbon
CoreAudio
CoreWLAN
CoreVideo
DisplayServices
IOKit
MediaRemote
SkyLight
];
makeFlags = [ target ];
installPhase = ''
runHook preInstall
mkdir -p $out/bin
cp ./bin/sketchybar $out/bin/sketchybar
runHook postInstall
'';
passthru = {
tests.version = testers.testVersion {
package = finalAttrs.finalPackage;
version = "sketchybar-v${finalAttrs.version}";
};
updateScript = nix-update-script { };
};
meta = {
description = "A highly customizable macOS status bar replacement";
homepage = "https://github.com/FelixKratz/SketchyBar";
license = lib.licenses.gpl3;
mainProgram = "sketchybar";
maintainers = with lib.maintainers; [
azuwis
khaneliman
];
platforms = lib.platforms.darwin;
};
})
|
