1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{
lib,
stdenv,
fetchFromGitHub,
rustPlatform,
cargo,
rustc,
alsa-lib,
appstream-glib,
blueprint-compiler,
desktop-file-utils,
gettext,
glib,
gst_all_1,
gtk4,
libadwaita,
libpulseaudio,
libhandy,
meson,
ninja,
nix-update-script,
openssl,
pkg-config,
wrapGAppsHook4,
}:
stdenv.mkDerivation rec {
pname = "spot";
version = "0.4.1";
src = fetchFromGitHub {
owner = "xou816";
repo = "spot";
rev = version;
hash = "sha256-F875e/VZyN8mTfe9lgjtILNxMqn+66XoPCdaEUagHyU=";
};
cargoDeps = rustPlatform.fetchCargoTarball {
inherit src;
name = "${pname}-${version}";
hash = "sha256-45Rqs2/tSWoyZVjFuygR5SxldjoqpprtOKEnMqJK+p8=";
};
nativeBuildInputs = [
cargo
rustc
appstream-glib
blueprint-compiler
desktop-file-utils
gettext
gtk4 # for gtk-update-icon-cache
glib # for glib-compile-schemas
meson
ninja
pkg-config
rustPlatform.cargoSetupHook
wrapGAppsHook4
];
buildInputs = [
alsa-lib
glib
gst_all_1.gst-plugins-base
gst_all_1.gstreamer
gtk4
libadwaita
libhandy
libpulseaudio
openssl
];
# https://github.com/xou816/spot/issues/313
mesonBuildType = "release";
passthru = {
updateScript = nix-update-script { };
};
meta = {
description = "Native Spotify client for the GNOME desktop";
homepage = "https://github.com/xou816/spot";
changelog = "https://github.com/xou816/spot/releases/tag/${src.rev}";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ getchoo ];
mainProgram = "spot";
platforms = lib.platforms.linux;
};
}
|
