1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{
lib,
stdenv,
config,
fetchFromGitHub,
rustPackages,
pkg-config,
openssl,
withALSA ? stdenv.isLinux,
alsa-lib,
withJack ? stdenv.isLinux,
libjack2,
withPulseAudio ? config.pulseaudio or stdenv.isLinux,
libpulseaudio,
withPortAudio ? stdenv.isDarwin,
portaudio,
withMpris ? stdenv.isLinux,
withKeyring ? true,
dbus,
nix-update-script,
testers,
spotifyd,
}:
rustPackages.rustPlatform.buildRustPackage rec {
pname = "spotifyd";
version = "0.3.5-unstable-2024-08-13";
src = fetchFromGitHub {
owner = "Spotifyd";
repo = "spotifyd";
rev = "e342328550779423382f35cd10a18b1c76b81f40";
hash = "sha256-eP783ZNdzePQuhQE8SWYHwqK8J4+fperDYXAHWM0hz8=";
};
cargoHash = "sha256-jmsfB96uWX4CzEsS2Grr2FCptMIebj2DSA5z6zG9AJg=";
nativeBuildInputs = [ pkg-config ];
buildInputs =
lib.optionals stdenv.isLinux [ openssl ]
++ lib.optional (withALSA || withJack) alsa-lib
++ lib.optional withJack libjack2
++ lib.optional withPulseAudio libpulseaudio
++ lib.optional withPortAudio portaudio
# The `dbus_keying` feature works on other platforms, but only requires
# `dbus` on Linux
++ lib.optional ((withMpris || withKeyring) && stdenv.isLinux) dbus;
buildNoDefaultFeatures = true;
buildFeatures =
lib.optional withALSA "alsa_backend"
++ lib.optional withJack "rodiojack_backend"
++ lib.optional withPulseAudio "pulseaudio_backend"
++ lib.optional withPortAudio "portaudio_backend"
++ lib.optional withMpris "dbus_mpris"
++ lib.optional withKeyring "dbus_keyring";
doCheck = false;
passthru = {
tests.version = testers.testVersion {
package = spotifyd;
version = builtins.head (lib.splitString "-" version);
};
updateScript = nix-update-script { extraArgs = [ "--version=branch" ]; };
};
meta = {
description = "Open source Spotify client running as a UNIX daemon";
homepage = "https://spotifyd.rs/";
changelog = "https://github.com/Spotifyd/spotifyd/blob/${src.rev}/CHANGELOG.md";
license = lib.licenses.gpl3Plus;
maintainers = with lib.maintainers; [
anderslundstedt
Br1ght0ne
getchoo
];
platforms = lib.platforms.unix;
mainProgram = "spotifyd";
};
}
|
