blob: 31402d58fa72cf16bc0c500b9720f00df9418a79 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
{
lib,
buildGoModule,
fetchFromGitHub,
installShellFiles,
}:
buildGoModule rec {
pname = "syft";
version = "1.8.0";
src = fetchFromGitHub {
owner = "anchore";
repo = "syft";
rev = "refs/tags/v${version}";
hash = "sha256-S61O/JxVu60GS/T9jVBuebn+EFBwB5jiSEkKV/h/S+s=";
# populate values that require us to use git. By doing this in postFetch we
# can delete .git afterwards and maintain better reproducibility of the src.
leaveDotGit = true;
postFetch = ''
cd "$out"
git rev-parse HEAD > $out/COMMIT
# 0000-00-00T00:00:00Z
date -u -d "@$(git log -1 --pretty=%ct)" "+%Y-%m-%dT%H:%M:%SZ" > $out/SOURCE_DATE_EPOCH
find "$out" -name .git -print0 | xargs -0 rm -rf
'';
};
# hash mismatch with darwin
proxyVendor = true;
vendorHash = "sha256-WSDbTI0U3Vqkfy8fxuqq9G5uBnBQ3421vyn6RriQx/U=";
nativeBuildInputs = [ installShellFiles ];
subPackages = [ "cmd/syft" ];
ldflags = [
"-s"
"-w"
"-X=main.version=${version}"
"-X=main.gitDescription=v${version}"
"-X=main.gitTreeState=clean"
];
postPatch = ''
# Don't check for updates.
substituteInPlace cmd/syft/internal/options/update_check.go \
--replace-fail "CheckForAppUpdate: true" "CheckForAppUpdate: false"
'';
preBuild = ''
ldflags+=" -X main.gitCommit=$(cat COMMIT)"
ldflags+=" -X main.buildDate=$(cat SOURCE_DATE_EPOCH)"
'';
# tests require a running docker instance
doCheck = false;
postInstall = ''
installShellCompletion --cmd syft \
--bash <($out/bin/syft completion bash) \
--fish <($out/bin/syft completion fish) \
--zsh <($out/bin/syft completion zsh)
'';
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/syft --help
$out/bin/syft version | grep "${version}"
runHook postInstallCheck
'';
meta = with lib; {
description = "CLI tool and library for generating a Software Bill of Materials from container images and filesystems";
homepage = "https://github.com/anchore/syft";
changelog = "https://github.com/anchore/syft/releases/tag/v${version}";
longDescription = ''
A CLI tool and Go library for generating a Software Bill of Materials
(SBOM) from container images and filesystems. Exceptional for
vulnerability detection when used with a scanner tool like Grype.
'';
license = with licenses; [ asl20 ];
maintainers = with maintainers; [
developer-guy
jk
kashw2
];
mainProgram = "syft";
};
}
|