blob: ff72272c6c536ac745dbdf0ac02dce8b2deb08bd (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
{ stdenv
, lib
, fetchurl
, copyDesktopItems
, makeDesktopItem
, makeWrapper
, jre
, libGL
, libpulseaudio
, libXxf86vm
}:
let
version = "4.13.2-redo";
desktopItem = makeDesktopItem {
name = "unciv";
exec = "unciv";
comment = "An open-source Android/Desktop remake of Civ V";
desktopName = "Unciv";
icon = "unciv";
categories = [ "Game" ];
};
desktopIcon = fetchurl {
url = "https://github.com/yairm210/Unciv/blob/${version}/extraImages/Icons/Unciv%20icon%20v6.png?raw=true";
hash = "sha256-Zuz+HGfxjGviGBKTiHdIFXF8UMRLEIfM8f+LIB/xonk=";
};
envLibPath = lib.makeLibraryPath (lib.optionals stdenv.isLinux [
libGL
libpulseaudio
libXxf86vm
]);
in
stdenv.mkDerivation rec {
pname = "unciv";
inherit version;
src = fetchurl {
url = "https://github.com/yairm210/Unciv/releases/download/${version}/Unciv.jar";
hash = "sha256-bZXBgSjmW+fBdDfG7cqKkF4VLYw7Iq2mw5j6iDh2ZhY=";
};
dontUnpack = true;
nativeBuildInputs = [ copyDesktopItems makeWrapper ];
installPhase = ''
runHook preInstall
makeWrapper ${jre}/bin/java $out/bin/unciv \
--prefix LD_LIBRARY_PATH : "${envLibPath}" \
--prefix PATH : ${lib.makeBinPath [ jre ]} \
--add-flags "-jar ${src}"
install -Dm444 ${desktopIcon} $out/share/icons/hicolor/512x512/apps/unciv.png
runHook postInstall
'';
desktopItems = [ desktopItem ];
meta = with lib; {
description = "Open-source Android/Desktop remake of Civ V";
mainProgram = "unciv";
homepage = "https://github.com/yairm210/Unciv";
maintainers = with maintainers; [ tex ];
sourceProvenance = with sourceTypes; [ binaryBytecode ];
license = licenses.mpl20;
platforms = platforms.all;
};
}
|
