blob: d986353a2bdac6566c7abaeb4cdb2d259d16510b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{ lib
, fetchurl
, makeWrapper
, stdenv
, undmg
, variant ?
if (stdenv.isDarwin && stdenv.isAarch64)
then "arm64"
else if (stdenv.isDarwin && stdenv.isx86_64)
then "intel64"
else "universal" # not reachable by normal means
}:
assert builtins.elem variant [ "arm64" "intel64" "universal" ];
stdenv.mkDerivation (finalAttrs: {
pname = "vlc-bin-${variant}";
version = "3.0.20";
src = fetchurl {
url = "http://get.videolan.org/vlc/${finalAttrs.version}/macosx/vlc-${finalAttrs.version}-${variant}.dmg";
hash = {
"arm64" = "sha256-XV8O5S2BmCpiL0AhkopktHBalVRJniDDPQusIlkLEY4=";
"intel64" = "sha256-pNwUQfyrjiuQxil0zlOZu4isv2xw1U8hxhWNn7H7onk=";
"universal" = "sha256-IqGPOWzMmHbGDV+0QxFslv19BC2J1Z5Qzcuja/Od1Us=";
}.${variant};
};
sourceRoot = ".";
nativeBuildInputs = [
makeWrapper
undmg
];
installPhase = ''
runHook preInstall
mkdir -p $out/Applications $out/bin
cp -r "VLC.app" $out/Applications
makeWrapper "$out/Applications/VLC.app/Contents/MacOS/VLC" "$out/bin/vlc"
runHook postInstall
'';
meta = {
description = "Cross-platform media player and streaming server; precompiled binary for MacOS, repacked from official website";
homepage = "https://www.videolan.org/vlc/";
downloadPage = "https://www.videolan.org/vlc/download-macosx.html";
license = lib.licenses.lgpl21Plus;
mainProgram = "vlc";
maintainers = with lib.maintainers; [ pcasaretto ];
platforms = lib.systems.inspect.patternLogicalAnd
(lib.systems.inspect.patterns.isDarwin)
(({
"arm64" = lib.systems.inspect.patterns.isAarch64;
"intel64" = lib.systems.inspect.patterns.isx86_64;
"universal" = lib.systems.inspect.patterns.isDarwin;
}).${variant});
sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
};
})
|
