pkgs/by-name/vw/vwsfriend/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

{
  lib,
  python3,
  fetchFromGitHub,
}:

python3.pkgs.buildPythonApplication rec {
  pname = "vwsfriend";
  version = "0.24.5";
  pyproject = true;

  src = fetchFromGitHub {
    owner = "tillsteinbach";
    repo = "VWsFriend";
    rev = "refs/tags/v${version}";
    hash = "sha256-bKL0ExHV/wz3qwB5pMgZDkASr93sCUb01uTipkE5iJU=";
  };

  sourceRoot = "${src.name}/vwsfriend";

  postPatch = ''
    # we don't need pytest-runner, pylint, etc.
    true > setup_requirements.txt

    substituteInPlace requirements.txt \
      --replace-fail psycopg2-binary psycopg2
  '';

  build-system = with python3.pkgs; [ setuptools ];

  pythonRelaxDeps = true;

  dependencies =
    with python3.pkgs;
    [
      weconnect
      hap-python
      pypng
      sqlalchemy
      psycopg2
      requests
      werkzeug
      flask
      flask-login
      flask-caching
      wtforms
      flask-wtf
      flask-sqlalchemy
      alembic
      haversine
    ]
    ++ weconnect.optional-dependencies.Images
    ++ hap-python.optional-dependencies.QRCode;

  meta = {
    changelog = "https://github.com/tillsteinbach/VWsFriend/blob/${src.rev}/CHANGELOG.md";
    description = "VW WeConnect visualization and control";
    homepage = "https://github.com/tillsteinbach/VWsFriend";
    license = lib.licenses.mit;
    mainProgram = "vwsfriend";
    maintainers = with lib.maintainers; [ dotlambda ];
  };
}