blob: fd1603e08d28a7a16ce66e9b03f7a372e2f42985 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
{ lib
, stdenvNoCC
, fetchFromGitHub
, gtk3
, breeze-icons
, elementary-icon-theme
, hicolor-icon-theme
, papirus-folders
, color ? null
, withElementary ? false
, gitUpdater
}:
stdenvNoCC.mkDerivation rec {
pname = "papirus-icon-theme";
version = "20240501";
src = fetchFromGitHub {
owner = "PapirusDevelopmentTeam";
repo = pname;
rev = version;
hash = "sha256-ZTijLslItfXRBUVKrz9KcOc78Efr5rRV+HfQckKcZSI=";
};
nativeBuildInputs = [
gtk3
papirus-folders
];
propagatedBuildInputs = [
breeze-icons
hicolor-icon-theme
] ++ lib.optional withElementary [
elementary-icon-theme
];
dontDropIconThemeCache = true;
installPhase = ''
runHook preInstall
mkdir -p $out/share/icons
mv ${lib.optionalString withElementary "{,e}"}Papirus* $out/share/icons
for theme in $out/share/icons/*; do
${lib.optionalString (color != null) "${papirus-folders}/bin/papirus-folders -t $theme -o -C ${color}"}
gtk-update-icon-cache --force $theme
done
runHook postInstall
'';
passthru.updateScript = gitUpdater { };
meta = with lib; {
description = "Pixel perfect icon theme for Linux";
homepage = "https://github.com/PapirusDevelopmentTeam/papirus-icon-theme";
license = licenses.gpl3Only;
# darwin gives hash mismatch in source, probably because of file names differing only in case
platforms = platforms.linux;
maintainers = with maintainers; [ romildo moni ];
};
}
|
