blob: 91c485ce1154dd959d1756d658155feb3116b97b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
{ lib
, stdenvNoCC
, buildGoModule
, fetchFromGitHub
, dbip-country-lite
}:
let
generator = buildGoModule rec {
pname = "sing-geoip";
version = "unstable-2022-07-05";
src = fetchFromGitHub {
owner = "SagerNet";
repo = pname;
rev = "2ced72c94da4c9259c40353c375319d9d28a78f3";
hash = "sha256-z8aP+OfTuzQNwOT3EEnI9uze/vbHTJLEiCPqIrnNUHw=";
};
vendorHash = "sha256-lr0XMLFxJmLqIqCuGgmsFh324jmZVj71blmStMn41Rs=";
postPatch = ''
# The codes args should start from the third args
substituteInPlace main.go --replace "os.Args[2:]" "os.Args[3:]"
'';
meta = with lib; {
description = "GeoIP data for sing-box";
homepage = "https://github.com/SagerNet/sing-geoip";
license = licenses.gpl3Plus;
maintainers = with maintainers; [ linsui ];
};
};
in
stdenvNoCC.mkDerivation rec {
inherit (generator) pname;
inherit (dbip-country-lite) version;
dontUnpack = true;
nativeBuildInputs = [ generator ];
buildPhase = ''
runHook preBuild
${pname} ${dbip-country-lite.mmdb} geoip.db
${pname} ${dbip-country-lite.mmdb} geoip-cn.db cn
runHook postBuild
'';
installPhase = ''
runHook preInstall
install -Dm644 geoip.db $out/share/sing-box/geoip.db
install -Dm644 geoip-cn.db $out/share/sing-box/geoip-cn.db
runHook postInstall
'';
passthru = { inherit generator; };
meta = generator.meta // {
inherit (dbip-country-lite.meta) license;
};
}
|