1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
{ type
, version
, srcs
, icu # passing icu as an argument, because dotnet 3.1 has troubles with icu71
, packages ? null
}:
assert builtins.elem type [ "aspnetcore" "runtime" "sdk" ];
assert if type == "sdk" then packages != null else true;
{ lib
, stdenv
, fetchurl
, writeText
, autoPatchelfHook
, makeWrapper
, libunwind
, openssl_1_1
, libuuid
, zlib
, libkrb5
, curl
, lttng-ust_2_12
, testers
, runCommand
, writeShellScript
}:
let
pname =
if type == "aspnetcore" then
"aspnetcore-runtime"
else if type == "runtime" then
"dotnet-runtime"
else
"dotnet-sdk";
descriptions = {
aspnetcore = "ASP.NET Core Runtime ${version}";
runtime = ".NET Runtime ${version}";
sdk = ".NET SDK ${version}";
};
in
stdenv.mkDerivation (finalAttrs: rec {
inherit pname version;
# Some of these dependencies are `dlopen()`ed.
nativeBuildInputs = [
makeWrapper
] ++ lib.optional stdenv.isLinux autoPatchelfHook;
buildInputs = [
stdenv.cc.cc
zlib
icu
libkrb5
# this must be before curl for autoPatchElf to find it
# curl brings in its own openssl
openssl_1_1
curl
] ++ lib.optional stdenv.isLinux lttng-ust_2_12;
src = fetchurl (
srcs."${stdenv.hostPlatform.system}" or (throw
"Missing source (url and hash) for host system: ${stdenv.hostPlatform.system}")
);
sourceRoot = ".";
dontPatchELF = true;
noDumpEnvVars = true;
installPhase = ''
runHook preInstall
mkdir -p $out/bin
cp -r ./ $out
mkdir -p $out/share/doc/$pname/$version
mv $out/LICENSE.txt $out/share/doc/$pname/$version/
mv $out/ThirdPartyNotices.txt $out/share/doc/$pname/$version/
ln -s $out/dotnet $out/bin/dotnet
runHook postInstall
'';
doInstallCheck = true;
installCheckPhase = ''
$out/bin/dotnet --info
'';
# Tell autoPatchelf about runtime dependencies.
# (postFixup phase is run before autoPatchelfHook.)
postFixup = lib.optionalString stdenv.isLinux ''
patchelf \
--add-needed libicui18n.so \
--add-needed libicuuc.so \
$out/shared/Microsoft.NETCore.App/*/libcoreclr.so \
$out/shared/Microsoft.NETCore.App/*/*System.Globalization.Native.so \
$out/packs/Microsoft.NETCore.App.Host.linux-x64/*/runtimes/linux-x64/native/singlefilehost
patchelf \
--add-needed libgssapi_krb5.so \
$out/shared/Microsoft.NETCore.App/*/*System.Net.Security.Native.so \
$out/packs/Microsoft.NETCore.App.Host.linux-x64/*/runtimes/linux-x64/native/singlefilehost
patchelf \
--add-needed libssl.so \
$out/shared/Microsoft.NETCore.App/*/*System.Security.Cryptography.Native.OpenSsl.so \
$out/packs/Microsoft.NETCore.App.Host.linux-x64/*/runtimes/linux-x64/native/singlefilehost
'';
setupHook = writeText "dotnet-setup-hook" ''
if [ ! -w "$HOME" ]; then
export HOME=$(mktemp -d) # Dotnet expects a writable home directory for its configuration files
fi
export DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1 # Dont try to expand NuGetFallbackFolder to disk
export DOTNET_NOLOGO=1 # Disables the welcome message
export DOTNET_CLI_TELEMETRY_OPTOUT=1
'';
passthru = rec {
inherit icu packages;
runtimeIdentifierMap = {
"x86_64-linux" = "linux-x64";
"aarch64-linux" = "linux-arm64";
"x86_64-darwin" = "osx-x64";
"aarch64-darwin" = "osx-arm64";
};
updateScript =
if type != "sdk" then
lib.warn "${pname}-${version}: only the SDK package can be updated - this script will do nothing!"
writeShellScript "dummy-update" ''
echo "Doing nothing..."
echo "Run the updateScript from the SDK package"
''
else
let
majorVersion =
with lib;
concatStringsSep "." (take 2 (splitVersion version));
in
writeShellScript "update-dotnet-${majorVersion}" ''
pushd pkgs/development/compilers/dotnet
exec ${./update.sh} "${majorVersion}"
'';
# Convert a "stdenv.hostPlatform.system" to a dotnet RID
systemToDotnetRid = system: runtimeIdentifierMap.${system} or (throw "unsupported platform ${system}");
tests = {
version = testers.testVersion {
package = finalAttrs.finalPackage;
};
smoke-test = runCommand "dotnet-sdk-smoke-test" {
nativeBuildInputs = [ finalAttrs.finalPackage ];
} ''
HOME=$(pwd)/fake-home
dotnet new console
dotnet build
output="$(dotnet run)"
# yes, older SDKs omit the comma
[[ "$output" =~ Hello,?\ World! ]] && touch "$out"
'';
};
};
meta = with lib; {
description = builtins.getAttr type descriptions;
homepage = "https://dotnet.github.io/";
license = licenses.mit;
maintainers = with maintainers; [ kuznero mdarocha ];
mainProgram = "dotnet";
platforms = attrNames srcs;
};
})
|
