blob: 591c52e4c970cfc5df14bb2686ab567f6f83d089 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
{ stdenv
, lib
, fetchFromGitHub
, pkg-config
, python3
, libffi
, readline
}:
stdenv.mkDerivation rec {
pname = "micropython";
version = "1.19";
src = fetchFromGitHub {
owner = "micropython";
repo = "micropython";
rev = "v${version}";
sha256 = "sha256-M3cKNuRKOcB1lF9M1rDOpp3sPdx/I60ooLtOYmBWe7c=";
fetchSubmodules = true;
};
nativeBuildInputs = [ pkg-config python3 ];
buildInputs = [ libffi readline ];
buildPhase = ''
runHook preBuild
make -C mpy-cross
make -C ports/unix
runHook postBuild
'';
doCheck = true;
skippedTests = ""
+ lib.optionalString (stdenv.isDarwin) " -e uasyncio_basic -e uasyncio_heaplock -e uasyncio_wait_task"
+ lib.optionalString (stdenv.isDarwin && stdenv.isAarch64) " -e ffi_callback"
+ lib.optionalString (stdenv.isLinux && stdenv.isAarch64) " -e float_parse"
;
checkPhase = ''
runHook preCheck
pushd tests
${python3.interpreter} ./run-tests.py ${skippedTests}
popd
runHook postCheck
'';
installPhase = ''
runHook preInstall
mkdir -p $out/bin
install -Dm755 ports/unix/micropython -t $out/bin
runHook postInstall
'';
meta = with lib; {
description = "A lean and efficient Python implementation for microcontrollers and constrained systems";
homepage = "https://micropython.org";
platforms = platforms.unix;
license = licenses.mit;
maintainers = with maintainers; [ prusnak sgo ];
};
}
|