blob: ac425092128c619f550e82a195c4d59eb0326e3a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
{ stdenv, lib, fetchFromGitHub, cmake, gflags, gtest, perl }:
stdenv.mkDerivation rec {
pname = "glog";
version = "0.6.0";
src = fetchFromGitHub {
owner = "google";
repo = "glog";
rev = "v${version}";
sha256 = "sha256-xqRp9vaauBkKz2CXbh/Z4TWqhaUtqfbsSlbYZR/kW9s=";
};
nativeBuildInputs = [ cmake ];
buildInputs = [ gtest ];
propagatedBuildInputs = [ gflags ];
cmakeFlags = [
"-DBUILD_SHARED_LIBS=ON"
# glog's custom FindUnwind.cmake module detects LLVM's unwind in case
# stdenv.cc is clang. But the module doesn't get installed, causing
# consumers of the CMake config file to fail at the configuration step.
# Explicitly disabling unwind support sidesteps the issue.
"-DWITH_UNWIND=OFF"
];
doCheck = true;
# There are some non-thread safe tests that can fail
enableParallelChecking = false;
nativeCheckInputs = [ perl ];
env.GTEST_FILTER =
let
filteredTests = lib.optionals stdenv.hostPlatform.isMusl [
"Symbolize.SymbolizeStackConsumption"
"Symbolize.SymbolizeWithDemanglingStackConsumption"
] ++ lib.optionals stdenv.hostPlatform.isStatic [
"LogBacktraceAt.DoesBacktraceAtRightLineWhenEnabled"
] ++ lib.optionals stdenv.cc.isClang [
# Clang optimizes an expected allocation away.
# See https://github.com/google/glog/issues/937
"DeathNoAllocNewHook.logging"
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
"LogBacktraceAt.DoesBacktraceAtRightLineWhenEnabled"
];
in
"-${builtins.concatStringsSep ":" filteredTests}";
checkPhase =
let
excludedTests = lib.optionals stdenv.hostPlatform.isDarwin [
"mock-log"
] ++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
"logging" # works around segfaults on aarch64-darwin for now
];
excludedTestsRegex = lib.optionalString (excludedTests != [ ]) "(${lib.concatStringsSep "|" excludedTests})";
in
''
runHook preCheck
ctest -E "${excludedTestsRegex}" --output-on-failure
runHook postCheck
'';
meta = with lib; {
homepage = "https://github.com/google/glog";
license = licenses.bsd3;
description = "Library for application-level logging";
platforms = platforms.unix;
maintainers = with maintainers; [ nh2 r-burns ];
};
}
|
