blob: 1f7e8fdf2c49ba75d5053566408c3206b0cc04ea (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{ lib
, stdenv
, fetchFromGitHub
, python
, cmake
, ninja
}:
let
pyEnv = python.withPackages (ps: [ ps.setuptools ps.tomli ps.pip ps.setuptools ]);
in
stdenv.mkDerivation rec {
pname = "lief";
version = "0.15.1";
src = fetchFromGitHub {
owner = "lief-project";
repo = "LIEF";
rev = version;
sha256 = "sha256-2W/p6p7YXqSNaVs8yPAnLQhbBVIQWEbUVnhx9edV5gI=";
};
outputs = [ "out" "py" ];
nativeBuildInputs = [
cmake
ninja
];
# Not a propagatedBuildInput because only the $py output needs it; $out is
# just the library itself (e.g. C/C++ headers).
buildInputs = with python.pkgs; [
python
build
pathspec
pip
pydantic
scikit-build-core
];
env.CXXFLAGS = toString (lib.optional stdenv.isDarwin [ "-faligned-allocation" "-fno-aligned-new" "-fvisibility=hidden" ]);
postBuild = ''
pushd ../api/python
${pyEnv.interpreter} -m build --no-isolation --wheel --skip-dependency-check --config-setting=--parallel=$NIX_BUILD_CORES
popd
'';
postInstall = ''
pushd ../api/python
${pyEnv.interpreter} -m pip install --prefix $py dist/*.whl
popd
'';
meta = with lib; {
description = "Library to Instrument Executable Formats";
homepage = "https://lief.quarkslab.com/";
license = [ licenses.asl20 ];
platforms = with platforms; linux ++ darwin;
maintainers = with maintainers; [ lassulus genericnerdyusername ];
};
}
|
