blob: 3185ff4158ee95410edb8d43ed19199f41d286de (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
{ lib, stdenv, fetchurl, libxml2, pkg-config
, compressionSupport ? true, zlib ? null
, sslSupport ? true, openssl ? null
, static ? stdenv.hostPlatform.isStatic
, shared ? !stdenv.hostPlatform.isStatic
, bash
}:
assert compressionSupport -> zlib != null;
assert sslSupport -> openssl != null;
assert static || shared;
let
inherit (lib) optionals;
in
stdenv.mkDerivation rec {
version = "0.32.5";
pname = "neon";
src = fetchurl {
url = "https://notroj.github.io/${pname}/${pname}-${version}.tar.gz";
sha256 = "sha256-SHLhL4Alct7dSwL4cAZYFLLVFB99va9wju2rgmtRpYo=";
};
patches = optionals stdenv.isDarwin [ ./darwin-fix-configure.patch ];
nativeBuildInputs = [ pkg-config ];
buildInputs = [libxml2 openssl bash]
++ lib.optional compressionSupport zlib;
strictDeps = true;
configureFlags = [
(lib.enableFeature shared "shared")
(lib.enableFeature static "static")
(lib.withFeature compressionSupport "zlib")
(lib.withFeature sslSupport "ssl")
];
preConfigure = ''
export PKG_CONFIG="$(command -v "$PKG_CONFIG")"
'';
passthru = {inherit compressionSupport sslSupport;};
meta = with lib; {
description = "HTTP and WebDAV client library";
mainProgram = "neon-config";
homepage = "https://notroj.github.io/neon/";
changelog = "https://github.com/notroj/${pname}/blob/${version}/NEWS";
platforms = platforms.unix;
license = licenses.lgpl2;
};
}
|
