blob: 56562f771698f02df6ef948cf98ce7fd36002252 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, imath
, libdeflate
, pkg-config
, pkgsCross
}:
stdenv.mkDerivation rec {
pname = "openexr";
version = "3.2.4";
src = fetchFromGitHub {
owner = "AcademySoftwareFoundation";
repo = "openexr";
rev = "v${version}";
hash = "sha256-mVUxxYe6teiJ18PQ9703/kjBpJ9+a7vcDme+NwtQQQM=";
};
outputs = [ "bin" "dev" "out" "doc" ];
patches =
# Disable broken test on musl libc
# https://github.com/AcademySoftwareFoundation/openexr/issues/1556
lib.optional stdenv.hostPlatform.isMusl ./disable-iex-test.patch
;
# tests are determined to use /var/tmp on unix
postPatch = ''
cat <(find . -name tmpDir.h) <(echo src/test/OpenEXRCoreTest/main.cpp) | while read -r f ; do
substituteInPlace $f --replace '/var/tmp' "$TMPDIR"
done
'';
cmakeFlags = lib.optional stdenv.hostPlatform.isStatic "-DCMAKE_SKIP_RPATH=ON";
nativeBuildInputs = [ cmake pkg-config ];
propagatedBuildInputs = [ imath libdeflate ];
# Without 'sse' enforcement tests fail on i686 as due to excessive precision as:
# error reading back channel B pixel 21,-76 got -nan expected -nan
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isi686 "-msse2 -mfpmath=sse";
# https://github.com/AcademySoftwareFoundation/openexr/issues/1400
doCheck = !stdenv.hostPlatform.isAarch32;
passthru.tests = {
musl = pkgsCross.musl64.openexr_3;
};
meta = with lib; {
description = "High dynamic-range (HDR) image file format";
homepage = "https://www.openexr.com";
license = licenses.bsd3;
maintainers = with maintainers; [ paperdigits ];
platforms = platforms.all;
};
}
|
