blob: add7ef6fde22eaac581b360f658c56ea0c73cef2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, boost
, eigen
, collisionSupport ? !stdenv.isDarwin
, hpp-fcl
, urdfdom
, pythonSupport ? false
, python3Packages
}:
stdenv.mkDerivation (finalAttrs: {
pname = "pinocchio";
version = "2.7.0";
src = fetchFromGitHub {
owner = "stack-of-tasks";
repo = finalAttrs.pname;
rev = "v${finalAttrs.version}";
fetchSubmodules = true;
hash = "sha256-yhrG+MilGJkvwLUNTAgNhDqUWGjPswjrbg38yOLsmHc=";
};
strictDeps = true;
nativeBuildInputs = [
cmake
];
propagatedBuildInputs = [
urdfdom
] ++ lib.optionals (!pythonSupport) [
boost
eigen
] ++ lib.optionals (!pythonSupport && collisionSupport) [
hpp-fcl
] ++ lib.optionals pythonSupport [
python3Packages.boost
python3Packages.eigenpy
] ++ lib.optionals (pythonSupport && collisionSupport) [
python3Packages.hpp-fcl
];
cmakeFlags = lib.optionals collisionSupport [
"-DBUILD_WITH_COLLISION_SUPPORT=ON"
] ++ lib.optionals pythonSupport [
"-DBUILD_WITH_LIBPYTHON=ON"
] ++ lib.optionals (pythonSupport && stdenv.isDarwin) [
# AssertionError: '.' != '/tmp/nix-build-pinocchio-2.7.0.drv/sou[84 chars].dae'
"-DCMAKE_CTEST_ARGUMENTS='--exclude-regex;test-py-bindings_geometry_model_urdf'"
] ++ lib.optionals (!pythonSupport) [
"-DBUILD_PYTHON_INTERFACE=OFF"
];
doCheck = true;
pythonImportsCheck = lib.optionals (!pythonSupport) [
"pinocchio"
];
meta = with lib; {
description = "A fast and flexible implementation of Rigid Body Dynamics algorithms and their analytical derivatives";
homepage = "https://github.com/stack-of-tasks/pinocchio";
license = licenses.bsd2;
maintainers = with maintainers; [ nim65s wegank ];
platforms = platforms.unix;
};
})
|
