blob: 9aa239458502042c0f2ebded497d624b10d57b90 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, doxygen
, graphviz
, gtest
, valgrind
}:
stdenv.mkDerivation (finalAttrs: {
pname = "rapidjson";
version = "unstable-2024-04-09";
outputs = [
"out"
"doc"
];
src = fetchFromGitHub {
owner = "Tencent";
repo = "rapidjson";
rev = "ab1842a2dae061284c0a62dca1cc6d5e7e37e346";
hash = "sha256-kAGVJfDHEUV2qNR1LpnWq3XKBJy4hD3Swh6LX5shJpM=";
};
patches = [
./use-nixpkgs-gtest.patch
# https://github.com/Tencent/rapidjson/issues/2214
./suppress-valgrind-failures.patch
];
postPatch = ''
for f in doc/Doxyfile.*; do
substituteInPlace $f \
--replace-fail "WARN_IF_UNDOCUMENTED = YES" "WARN_IF_UNDOCUMENTED = NO"
done
'';
nativeBuildInputs = [
cmake
doxygen
graphviz
];
buildInputs = [
gtest
];
strictDeps = true;
cmakeFlags = [
(lib.cmakeBool "RAPIDJSON_BUILD_DOC" true)
(lib.cmakeBool "RAPIDJSON_BUILD_TESTS" true)
(lib.cmakeBool "RAPIDJSON_BUILD_EXAMPLES" true)
# gtest 1.13+ requires C++14 or later.
(lib.cmakeBool "RAPIDJSON_BUILD_CXX11" false)
(lib.cmakeBool "RAPIDJSON_BUILD_CXX17" true)
# Prevent -march=native
(lib.cmakeBool "RAPIDJSON_ENABLE_INSTRUMENTATION_OPT" false)
# Disable -Werror by using build type specific flags, which are
# added after general CMAKE_CXX_FLAGS.
(lib.cmakeFeature "CMAKE_CXX_FLAGS_RELEASE" "-Wno-error")
];
doCheck = !(stdenv.hostPlatform.isStatic || stdenv.isDarwin);
nativeCheckInputs = [
valgrind
];
meta = with lib; {
description = "Fast JSON parser/generator for C++ with both SAX/DOM style API";
homepage = "http://rapidjson.org/";
license = licenses.mit;
platforms = platforms.unix;
maintainers = with maintainers; [ dotlambda Madouura tobim ];
};
})
|
