blob: c0122a0d3d9dcfc6c89d66102a2bf7ef652e6fe5 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
{ lib
, fetchPypi
, buildPythonPackage
, pytestCheckHook
, dotnetCorePackages
, setuptools
, setuptools-scm
, wheel
, buildDotnetModule
, cffi
}:
let
pname = "clr-loader";
version = "0.2.6";
src = fetchPypi {
pname = "clr_loader";
inherit version;
hash = "sha256-AZNIrmtqg8ekBtFFN8J3zs96OlOyY+w0LIHe1YRaZ+4=";
};
# This buildDotnetModule is used only to get nuget sources, the actual
# build is done in `buildPythonPackage` below.
dotnet-build = buildDotnetModule {
inherit pname version src;
projectFile = [ "netfx_loader/ClrLoader.csproj" "example/example.csproj" ];
nugetDeps = ./deps.nix;
};
in
buildPythonPackage {
inherit pname version src;
format = "pyproject";
nativeBuildInputs = [
setuptools
setuptools-scm
wheel
dotnetCorePackages.sdk_6_0
];
propagatedBuildInputs = [
cffi
];
nativeCheckInputs = [
pytestCheckHook
];
disabledTests = [
# TODO: mono does not work due to https://github.com/NixOS/nixpkgs/issues/7307
"test_mono"
"test_mono_debug"
"test_mono_signal_chaining"
"test_mono_set_dir"
];
# Perform dotnet restore based on the nuget-source
preConfigure = ''
dotnet restore "netfx_loader/ClrLoader.csproj" \
-p:ContinuousIntegrationBuild=true \
-p:Deterministic=true \
--source "${dotnet-build.nuget-source}"
dotnet restore "example/example.csproj" \
-p:ContinuousIntegrationBuild=true \
-p:Deterministic=true \
--source "${dotnet-build.nuget-source}"
'';
passthru.fetch-deps = dotnet-build.fetch-deps;
meta = with lib; {
description = "Generic pure Python loader for .NET runtimes";
homepage = "https://pythonnet.github.io/clr-loader/";
license = licenses.mit;
maintainers = with maintainers; [ mdarocha ];
};
}
|