blob: 2d3333ecec6a3bd74917a72abc7c0be8a0a5dca8 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{
lib,
stdenv,
buildPythonPackage,
fetchPypi,
setuptools,
python,
pkg-config,
gdb,
numpy,
ncurses,
# Reverse dependency
sage,
}:
let
excludedTests =
[ "reimport_from_subinterpreter" ]
# cython's testsuite is not working very well with libc++
# We are however optimistic about things outside of testsuite still working
++ lib.optionals (stdenv.cc.isClang or false) [
"cpdef_extern_func"
"libcpp_algo"
]
# Some tests in the test suite isn't working on aarch64. Disable them for
# now until upstream finds a workaround.
# Upstream issue here: https://github.com/cython/cython/issues/2308
++ lib.optionals stdenv.isAarch64 [ "numpy_memoryview" ]
++ lib.optionals stdenv.isi686 [
"future_division"
"overflow_check_longlong"
];
in
buildPythonPackage rec {
pname = "cython";
version = "3.0.11";
pyproject = true;
src = fetchPypi {
pname = "cython";
inherit version;
hash = "sha256-cUbdKvhoK0ymEzGFHmrrzp/lFY51MAND+AwHyoCx+v8=";
};
build-system = [
pkg-config
setuptools
];
nativeCheckInputs = [
gdb
numpy
ncurses
];
env.LC_ALL = "en_US.UTF-8";
checkPhase = ''
export HOME="$NIX_BUILD_TOP"
${python.interpreter} runtests.py -j$NIX_BUILD_CORES \
--no-code-style \
${
lib.optionalString (
builtins.length excludedTests != 0
) ''--exclude="(${builtins.concatStringsSep "|" excludedTests})"''
}
'';
# https://github.com/cython/cython/issues/2785
# Temporary solution
doCheck = false;
# doCheck = !stdenv.isDarwin;
passthru.tests = {
inherit sage;
};
# force regeneration of generated code in source distributions
# https://github.com/cython/cython/issues/5089
setupHook = ./setup-hook.sh;
meta = {
changelog = "https://github.com/cython/cython/blob/${version}/CHANGES.rst";
description = "Optimising static compiler for both the Python programming language and the extended Cython programming language";
homepage = "https://cython.org";
license = lib.licenses.asl20;
};
}
|
