1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
{
lib,
stdenv,
buildPythonPackage,
fetchFromGitHub,
nix-update-script,
pythonOlder,
# pyproject
hatchling,
hatch-requirements-txt,
hatch-fancy-pypi-readme,
# runtime
setuptools,
fsspec,
httpx,
huggingface-hub,
packaging,
typing-extensions,
websockets,
# checkInputs
pytestCheckHook,
pytest-asyncio,
pydub,
rich,
tomlkit,
gradio,
}:
buildPythonPackage rec {
pname = "gradio-client";
version = "1.3.0";
pyproject = true;
disabled = pythonOlder "3.8";
# no tests on pypi
src = fetchFromGitHub {
owner = "gradio-app";
repo = "gradio";
# not to be confused with @gradio/client@${version}
rev = "refs/tags/gradio_client@${version}";
sparseCheckout = [ "client/python" ];
hash = "sha256-UZQWguUN3l0cj2wb2f7A61RTLy9nPYcIEwHIo+F1kR0=";
};
prePatch = ''
cd client/python
'';
# upstream adds upper constraints because they can, not because the need to
# https://github.com/gradio-app/gradio/pull/4885
pythonRelaxDeps = [
# only backward incompat is dropping py3.7 support
"websockets"
];
build-system = [
hatchling
hatch-requirements-txt
hatch-fancy-pypi-readme
];
dependencies = [
setuptools # needed for 'pkg_resources'
fsspec
httpx
huggingface-hub
packaging
typing-extensions
websockets
];
nativeCheckInputs = [
pytestCheckHook
pytest-asyncio
pydub
rich
tomlkit
gradio.sans-reverse-dependencies
];
# ensuring we don't propagate this intermediate build
disallowedReferences = [ gradio.sans-reverse-dependencies ];
# Add a pytest hook skipping tests that access network, marking them as "Expected fail" (xfail).
preCheck = ''
export HOME=$TMPDIR
cat ${./conftest-skip-network-errors.py} >> test/conftest.py
'';
pytestFlagsArray = [
"test/"
"-m 'not flaky'"
#"-x" "-W" "ignore" # uncomment for debugging help
];
disabledTests = lib.optionals stdenv.hostPlatform.isDarwin [
# flaky: OSError: Cannot find empty port in range: 7860-7959
"test_layout_components_in_output"
"test_layout_and_state_components_in_output"
"test_upstream_exceptions"
"test_httpx_kwargs"
];
pythonImportsCheck = [ "gradio_client" ];
__darwinAllowLocalNetworking = true;
passthru.updateScript = nix-update-script {
extraArgs = [ "--version-regex" "gradio_client@(.*)" ];
};
meta = with lib; {
homepage = "https://www.gradio.app/";
description = "Lightweight library to use any Gradio app as an API";
license = licenses.asl20;
maintainers = with maintainers; [ pbsds ];
};
}
|
