blob: 15685c8c66bcdff65b685e8d36459c8d020f802e (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
{
lib,
buildPythonPackage,
fetchFromGitHub,
pythonOlder,
hatchling,
pydantic,
python-dotenv,
pytestCheckHook,
pytest-examples,
pytest-mock,
}:
let
self = buildPythonPackage rec {
pname = "pydantic-settings";
version = "2.2.1";
pyproject = true;
disabled = pythonOlder "3.8";
src = fetchFromGitHub {
owner = "pydantic";
repo = "pydantic-settings";
rev = "refs/tags/v${version}";
hash = "sha256-4o8LlIFVizoxb484lVT67e24jhtUl49otr1lX/2zZ4M=";
};
nativeBuildInputs = [ hatchling ];
propagatedBuildInputs = [
pydantic
python-dotenv
];
pythonImportsCheck = [ "pydantic_settings" ];
nativeCheckInputs = [
pytestCheckHook
pytest-examples
pytest-mock
];
disabledTests = [
# expected to fail
"test_docs_examples[docs/index.md:212-246]"
];
preCheck = ''
export HOME=$TMPDIR
'';
# ruff is a dependency of pytest-examples which is required to run the tests.
# We do not want all of the downstream packages that depend on pydantic-settings to also depend on ruff.
doCheck = false;
passthru.tests = {
pytest = self.overridePythonAttrs { doCheck = true; };
};
meta = with lib; {
description = "Settings management using pydantic";
homepage = "https://github.com/pydantic/pydantic-settings";
license = licenses.mit;
broken = lib.versionOlder pydantic.version "2.0.0";
maintainers = with maintainers; [ ];
};
};
in
self
|