1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
|
{
lib,
stdenv,
cmake,
cups,
ninja,
python,
pythonImportsCheckHook,
moveBuildTree,
shiboken6,
llvmPackages,
symlinkJoin,
libGL,
darwin,
}:
let
packages = with python.pkgs.qt6; [
# required
python.pkgs.ninja
python.pkgs.packaging
python.pkgs.setuptools
qtbase
# optional
qt3d
qtcharts
qtconnectivity
qtdatavis3d
qtdeclarative
qthttpserver
qtmultimedia
qtnetworkauth
qtquick3d
qtremoteobjects
qtscxml
qtsensors
qtspeech
qtsvg
qtwebchannel
qtwebsockets
qtpositioning
qtlocation
qtshadertools
qtserialport
qtserialbus
qtgraphs
qttools
];
qt_linked = symlinkJoin {
name = "qt_linked";
paths = packages;
};
in
stdenv.mkDerivation (finalAttrs: {
pname = "pyside6";
inherit (shiboken6) version src;
sourceRoot = "pyside-setup-everywhere-src-${finalAttrs.version}/sources/pyside6";
# cmake/Macros/PySideModules.cmake supposes that all Qt frameworks on macOS
# reside in the same directory as QtCore.framework, which is not true for Nix.
# We therefore symLink all required and optional Qt modules in one directory tree ("qt_linked").
# Also we remove "Designer" from darwin build, due to linking failure
postPatch =
''
# Don't ignore optional Qt modules
substituteInPlace cmake/PySideHelpers.cmake \
--replace-fail \
'string(FIND "''${_module_dir}" "''${_core_abs_dir}" found_basepath)' \
'set (found_basepath 0)'
''
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
substituteInPlace cmake/PySideHelpers.cmake \
--replace-fail \
"Designer" ""
'';
# "Couldn't find libclang.dylib You will likely need to add it manually to PATH to ensure the build succeeds."
env = lib.optionalAttrs stdenv.hostPlatform.isDarwin {
LLVM_INSTALL_DIR = "${llvmPackages.libclang.lib}/lib";
};
nativeBuildInputs = [
cmake
ninja
python
pythonImportsCheckHook
] ++ lib.optionals stdenv.hostPlatform.isDarwin [ moveBuildTree ];
buildInputs =
if stdenv.hostPlatform.isLinux then
# qtwebengine fails under darwin
# see https://github.com/NixOS/nixpkgs/pull/312987
packages ++ [ python.pkgs.qt6.qtwebengine ]
else
with darwin.apple_sdk_11_0.frameworks;
[
qt_linked
libGL
cups
# frameworks
IOKit
DiskArbitration
CoreBluetooth
EventKit
AVFoundation
Contacts
AGL
AppKit
];
propagatedBuildInputs = [ shiboken6 ];
cmakeFlags = [ "-DBUILD_TESTS=OFF" ];
dontWrapQtApps = true;
postInstall = ''
cd ../../..
${python.pythonOnBuildForHost.interpreter} setup.py egg_info --build-type=pyside6
cp -r PySide6.egg-info $out/${python.sitePackages}/
'';
pythonImportsCheck = [ "PySide6" ];
meta = {
description = "Python bindings for Qt";
license = with lib.licenses; [
lgpl3Only
gpl2Only
gpl3Only
];
homepage = "https://wiki.qt.io/Qt_for_Python";
changelog = "https://code.qt.io/cgit/pyside/pyside-setup.git/tree/doc/changelogs/changes-${finalAttrs.version}?h=v${finalAttrs.version}";
maintainers = with lib.maintainers; [ gebner ];
platforms = lib.platforms.all;
};
})
|
