1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
{
lib,
buildPythonPackage,
callPackage,
pythonOlder,
fetchPypi,
writeText,
# build-system
setuptools,
setuptools-scm,
# dependencies
attrs,
exceptiongroup,
iniconfig,
packaging,
pluggy,
tomli,
# optional-dependencies
argcomplete,
hypothesis,
mock,
pygments,
requests,
xmlschema,
}:
buildPythonPackage rec {
pname = "pytest";
version = "8.2.2";
pyproject = true;
src = fetchPypi {
inherit pname version;
hash = "sha256-3ku4EE4gGTnM3GiLJ6iae+IHmyLivSsH+Aa2unEReXc=";
};
patches = [
# https://github.com/pytest-dev/pytest/issues/12424
# https://github.com/pytest-dev/pytest/pull/12436
./8.2.2-unittest-testcase-regression.patch
];
outputs = [
"out"
"testout"
];
nativeBuildInputs = [
setuptools
setuptools-scm
];
propagatedBuildInputs =
[
iniconfig
packaging
pluggy
]
++ lib.optionals (pythonOlder "3.11") [
exceptiongroup
tomli
];
passthru.optional-dependencies = {
testing = [
argcomplete
attrs
hypothesis
mock
pygments
requests
setuptools
xmlschema
];
};
postInstall = ''
mkdir $testout
cp -R testing $testout/testing
'';
doCheck = false;
passthru.tests.pytest = callPackage ./tests.nix { };
# Remove .pytest_cache when using py.test in a Nix build
setupHook = writeText "pytest-hook" ''
pytestcachePhase() {
find $out -name .pytest_cache -type d -exec rm -rf {} +
}
preDistPhases+=" pytestcachePhase"
# pytest generates it's own bytecode files to improve assertion messages.
# These files similar to cpython's bytecode files but are never laoded
# by python interpreter directly. We remove them for a few reasons:
# - files are non-deterministic: https://github.com/NixOS/nixpkgs/issues/139292
# (file headers are generatedt by pytest directly and contain timestamps)
# - files are not needed after tests are finished
pytestRemoveBytecodePhase () {
# suffix is defined at:
# https://github.com/pytest-dev/pytest/blob/7.2.1/src/_pytest/assertion/rewrite.py#L51-L53
find $out -name "*-pytest-*.py[co]" -delete
}
preDistPhases+=" pytestRemoveBytecodePhase"
'';
pythonImportsCheck = [ "pytest" ];
meta = with lib; {
description = "Framework for writing tests";
homepage = "https://docs.pytest.org";
changelog = "https://github.com/pytest-dev/pytest/releases/tag/${version}";
maintainers = with maintainers; [
domenkozar
lovek323
madjar
lsix
];
license = licenses.mit;
};
}
|