1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
{
lib,
stdenv,
autopep8,
buildPythonPackage,
docstring-to-markdown,
fetchFromGitHub,
flake8,
flaky,
importlib-metadata,
jedi,
matplotlib,
mccabe,
numpy,
pandas,
pluggy,
pycodestyle,
pydocstyle,
pyflakes,
pylint,
pyqt5,
pytestCheckHook,
python-lsp-jsonrpc,
pythonOlder,
rope,
setuptools,
setuptools-scm,
toml,
ujson,
websockets,
whatthepatch,
yapf,
}:
buildPythonPackage rec {
pname = "python-lsp-server";
version = "1.11.0";
format = "pyproject";
disabled = pythonOlder "3.8";
src = fetchFromGitHub {
owner = "python-lsp";
repo = "python-lsp-server";
rev = "refs/tags/v${version}";
hash = "sha256-0DFcnGlyDOK0Lxpr++xV6klhFF9b1fihH5FY/tblr+E=";
};
postPatch = ''
substituteInPlace pyproject.toml \
--replace-fail "--cov-report html --cov-report term --junitxml=pytest.xml" "" \
--replace-fail "--cov pylsp --cov test" ""
'';
pythonRelaxDeps = [
"autopep8"
"flake8"
"mccabe"
"pycodestyle"
"pydocstyle"
"pyflakes"
];
nativeBuildInputs = [ setuptools-scm ];
build-system = [ setuptools-scm ];
dependencies = [
docstring-to-markdown
jedi
pluggy
python-lsp-jsonrpc
setuptools # `pkg_resources`imported in pylsp/config/config.py
ujson
] ++ lib.optionals (pythonOlder "3.10") [ importlib-metadata ];
passthru.optional-dependencies = {
all = [
autopep8
flake8
mccabe
pycodestyle
pydocstyle
pyflakes
pylint
rope
toml
whatthepatch
yapf
];
autopep8 = [ autopep8 ];
flake8 = [ flake8 ];
mccabe = [ mccabe ];
pycodestyle = [ pycodestyle ];
pydocstyle = [ pydocstyle ];
pyflakes = [ pyflakes ];
pylint = [ pylint ];
rope = [ rope ];
yapf = [
whatthepatch
yapf
];
websockets = [ websockets ];
};
nativeCheckInputs =
[
flaky
matplotlib
numpy
pandas
pytestCheckHook
]
++ passthru.optional-dependencies.all
# pyqt5 is broken on aarch64-darwin
++ lib.optionals (!stdenv.isDarwin || !stdenv.isAarch64) [ pyqt5 ];
disabledTests =
[
# Don't run lint tests
"test_pydocstyle"
# https://github.com/python-lsp/python-lsp-server/issues/243
"test_numpy_completions"
"test_workspace_loads_pycodestyle_config"
"test_autoimport_code_actions_and_completions_for_notebook_document"
]
++ lib.optionals (stdenv.isDarwin && stdenv.isAarch64) [
# pyqt5 is broken on aarch64-darwin
"test_pyqt_completion"
];
preCheck = ''
export HOME=$(mktemp -d);
'';
pythonImportsCheck = [
"pylsp"
"pylsp.python_lsp"
];
meta = with lib; {
description = "Python implementation of the Language Server Protocol";
homepage = "https://github.com/python-lsp/python-lsp-server";
changelog = "https://github.com/python-lsp/python-lsp-server/blob/v${version}/CHANGELOG.md";
license = licenses.mit;
maintainers = with maintainers; [ fab ];
mainProgram = "pylsp";
};
}
|