1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
{ lib
, buildPythonPackage
, pythonOlder
, fetchPypi
, pythonRelaxDepsHook
, setuptools
, click
, requests
, packaging
, dparse
, ruamel-yaml
, pytestCheckHook
}:
buildPythonPackage rec {
pname = "safety";
version = "2.3.5";
disabled = pythonOlder "3.6";
format = "pyproject";
src = fetchPypi {
inherit pname version;
hash = "sha256-pgwR+JUvQSy7Fl1wyx9nOjtDorqak84R+X5qTeg0qjo=";
};
postPatch = ''
substituteInPlace safety/safety.py \
--replace "telemetry=True" "telemetry=False"
substituteInPlace safety/util.py \
--replace "telemetry=True" "telemetry=False"
substituteInPlace safety/cli.py \
--replace "telemetry', default=True" "telemetry', default=False"
'';
nativeBuildInputs = [
pythonRelaxDepsHook
setuptools
];
pythonRelaxDeps = [
"packaging"
];
propagatedBuildInputs = [
setuptools
click
requests
packaging
dparse
ruamel-yaml
];
nativeCheckInputs = [
pytestCheckHook
];
# Disable tests depending on online services
disabledTests = [
"test_announcements_if_is_not_tty"
"test_check_live"
"test_check_live_cached"
"test_check_vulnerabilities"
"test_license"
"test_chained_review"
];
preCheck = ''
export HOME=$(mktemp -d)
'';
meta = with lib; {
description = "Checks installed dependencies for known vulnerabilities";
homepage = "https://github.com/pyupio/safety";
changelog = "https://github.com/pyupio/safety/blob/${version}/CHANGELOG.md";
license = licenses.mit;
maintainers = with maintainers; [ thomasdesr dotlambda ];
};
}
|
