1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
|
{
lib,
stdenv,
botocore,
buildPythonPackage,
cryptography,
cssselect,
defusedxml,
fetchFromGitHub,
glibcLocales,
installShellFiles,
itemadapter,
itemloaders,
jmespath,
lxml,
packaging,
parsel,
pexpect,
protego,
pydispatcher,
pyopenssl,
pytest-xdist,
pytestCheckHook,
pythonOlder,
queuelib,
service-identity,
setuptools,
sybil,
testfixtures,
tldextract,
twisted,
uvloop,
w3lib,
zope-interface,
}:
buildPythonPackage rec {
pname = "scrapy";
version = "2.11.2";
pyproject = true;
disabled = pythonOlder "3.8";
src = fetchFromGitHub {
owner = "scrapy";
repo = "scrapy";
rev = "refs/tags/${version}";
hash = "sha256-EaO1kQ3VSTwEW+r0kSKycOxHNTPwwCVjch1ZBrTU0qQ=";
};
pythonRelaxDeps = [
"defusedxml"
];
nativeBuildInputs = [
installShellFiles
setuptools
];
propagatedBuildInputs = [
cryptography
cssselect
defusedxml
itemadapter
itemloaders
lxml
packaging
parsel
protego
pydispatcher
pyopenssl
queuelib
service-identity
tldextract
twisted
w3lib
zope-interface
];
nativeCheckInputs = [
botocore
glibcLocales
jmespath
pexpect
pytest-xdist
pytestCheckHook
sybil
testfixtures
uvloop
];
LC_ALL = "en_US.UTF-8";
disabledTestPaths = [
"tests/test_proxy_connect.py"
"tests/test_utils_display.py"
"tests/test_command_check.py"
# Don't test the documentation
"docs"
];
disabledTests =
[
# Requires network access
"AnonymousFTPTestCase"
"FTPFeedStorageTest"
"FeedExportTest"
"test_custom_asyncio_loop_enabled_true"
"test_custom_loop_asyncio"
"test_custom_loop_asyncio_deferred_signal"
"FileFeedStoragePreFeedOptionsTest" # https://github.com/scrapy/scrapy/issues/5157
"test_persist"
"test_timeout_download_from_spider_nodata_rcvd"
"test_timeout_download_from_spider_server_hangs"
"test_unbounded_response"
"CookiesMiddlewareTest"
# Test fails on Hydra
"test_start_requests_laziness"
]
++ lib.optionals stdenv.isDarwin [
"test_xmliter_encoding"
"test_download"
"test_reactor_default_twisted_reactor_select"
"URIParamsSettingTest"
"URIParamsFeedOptionTest"
# flaky on darwin-aarch64
"test_fixed_delay"
"test_start_requests_laziness"
];
postInstall = ''
installManPage extras/scrapy.1
installShellCompletion --cmd scrapy \
--zsh extras/scrapy_zsh_completion \
--bash extras/scrapy_bash_completion
'';
pythonImportsCheck = [ "scrapy" ];
__darwinAllowLocalNetworking = true;
meta = with lib; {
description = "High-level web crawling and web scraping framework";
mainProgram = "scrapy";
longDescription = ''
Scrapy is a fast high-level web crawling and web scraping framework, used to crawl
websites and extract structured data from their pages. It can be used for a wide
range of purposes, from data mining to monitoring and automated testing.
'';
homepage = "https://scrapy.org/";
changelog = "https://github.com/scrapy/scrapy/raw/${version}/docs/news.rst";
license = licenses.bsd3;
maintainers = with maintainers; [ vinnymeller ];
};
}
|