blob: a29afaaea40dd1a05635a278d842f5badbafaa91 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
{ lib, python3Packages, fetchPypi, installShellFiles }:
python3Packages.buildPythonApplication rec {
pname = "backblaze-b2";
version = "3.15.0";
format = "setuptools";
src = fetchPypi {
inherit version;
pname = "b2";
hash = "sha256-10c2zddALy7+CGxhjUC6tMLQcZ3WmLeRY1bNKWunAys=";
};
postPatch = ''
substituteInPlace requirements.txt \
--replace 'phx-class-registry==4.0.5' 'phx-class-registry'
substituteInPlace requirements.txt \
--replace 'tabulate==0.8.10' 'tabulate'
substituteInPlace setup.py \
--replace 'setuptools_scm<6.0' 'setuptools_scm'
'';
nativeBuildInputs = [
installShellFiles
python3Packages.setuptools-scm
];
propagatedBuildInputs = with python3Packages; [
argcomplete
arrow
b2sdk
phx-class-registry
docutils
rst2ansi
tabulate
tqdm
platformdirs
packaging
];
nativeCheckInputs = with python3Packages; [
backoff
more-itertools
pexpect
pytestCheckHook
];
preCheck = ''
export HOME=$(mktemp -d)
'';
disabledTests = [
# require network
"test_files_headers"
"test_integration"
# fixed by https://github.com/Backblaze/B2_Command_Line_Tool/pull/915
"TestRmConsoleTool"
];
disabledTestPaths = [
# requires network
"test/integration/test_b2_command_line.py"
# it's hard to make it work on nix
"test/integration/test_autocomplete.py"
"test/unit/console_tool"
];
postInstall = ''
mv "$out/bin/b2" "$out/bin/backblaze-b2"
installShellCompletion --cmd backblaze-b2 \
--bash <(${python3Packages.argcomplete}/bin/register-python-argcomplete backblaze-b2) \
--zsh <(${python3Packages.argcomplete}/bin/register-python-argcomplete backblaze-b2)
'';
meta = with lib; {
description = "Command-line tool for accessing the Backblaze B2 storage service";
homepage = "https://github.com/Backblaze/B2_Command_Line_Tool";
changelog = "https://github.com/Backblaze/B2_Command_Line_Tool/blob/v${version}/CHANGELOG.md";
license = licenses.mit;
maintainers = with maintainers; [ hrdinka kevincox tomhoule ];
};
}
|