1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
{ lib
, fetchpatch
, installShellFiles
, ninja
, pkg-config
, python3
, substituteAll
, withDarwinFrameworksGtkDocPatch ? false
}:
python3.pkgs.buildPythonApplication rec {
pname = "meson";
version = "0.61.2";
src = python3.pkgs.fetchPypi {
inherit pname version;
hash = "sha256-AjOn+NlZB5MY9gUrCTnCf2il3oa6YB8lye5oaftfWIk=";
};
patches = [
# Upstream insists on not allowing bindir and other dir options
# outside of prefix for some reason:
# https://github.com/mesonbuild/meson/issues/2561
# We remove the check so multiple outputs can work sanely.
./allow-dirs-outside-of-prefix.patch
# Meson is currently inspecting fewer variables than autoconf does, which
# makes it harder for us to use setup hooks, etc. Taken from
# https://github.com/mesonbuild/meson/pull/6827
./more-env-vars.patch
# Unlike libtool, vanilla Meson does not pass any information
# about the path library will be installed to to g-ir-scanner,
# breaking the GIR when path other than ${!outputLib}/lib is used.
# We patch Meson to add a --fallback-library-path argument with
# library install_dir to g-ir-scanner.
./gir-fallback-path.patch
# In common distributions, RPATH is only needed for internal libraries so
# meson removes everything else. With Nix, the locations of libraries
# are not as predictable, therefore we need to keep them in the RPATH.
# At the moment we are keeping the paths starting with /nix/store.
# https://github.com/NixOS/nixpkgs/issues/31222#issuecomment-365811634
(substituteAll {
src = ./fix-rpath.patch;
inherit (builtins) storeDir;
})
# When Meson removes build_rpath from DT_RUNPATH entry, it just writes
# the shorter NUL-terminated new rpath over the old one to reduce
# the risk of potentially breaking the ELF files.
# But this can cause much bigger problem for Nix as it can produce
# cut-in-half-by-\0 store path references.
# Let’s just clear the whole rpath and hope for the best.
./clear-old-rpath.patch
# Patch out default boost search paths to avoid impure builds on
# unsandboxed non-NixOS builds, see:
# https://github.com/NixOS/nixpkgs/issues/86131#issuecomment-711051774
./boost-Do-not-add-system-paths-on-nix.patch
] ++ lib.optionals withDarwinFrameworksGtkDocPatch [
# Fix building gtkdoc for GLib
# https://github.com/mesonbuild/meson/pull/10186
./fix-gtkdoc-when-using-multiple-apple-frameworks.patch
];
setupHook = ./setup-hook.sh;
# Meson included tests since 0.45, however they fail in Nixpkgs because they
# require a typical building environment (including C compiler and stuff).
# Just for the sake of documentation, the next lines are maintained here.
doCheck = false;
checkInputs = [ ninja pkg-config ];
checkPhase = ''
python ./run_project_tests.py
'';
postFixup = ''
pushd $out/bin
# undo shell wrapper as meson tools are called with python
for i in *; do
mv ".$i-wrapped" "$i"
done
popd
# Do not propagate Python
rm $out/nix-support/propagated-build-inputs
'';
nativeBuildInputs = [ installShellFiles ];
postInstall = ''
installShellCompletion --zsh data/shell-completions/zsh/_meson
installShellCompletion --bash data/shell-completions/bash/meson
'';
meta = with lib; {
homepage = "https://mesonbuild.com";
description = "An open source, fast and friendly build system made in Python";
longDescription = ''
Meson is an open source build system meant to be both extremely fast, and,
even more importantly, as user friendly as possible.
The main design point of Meson is that every moment a developer spends
writing or debugging build definitions is a second wasted. So is every
second spent waiting for the build system to actually start compiling
code.
'';
license = licenses.asl20;
maintainers = with maintainers; [ jtojnar mbe AndersonTorres ];
inherit (python3.meta) platforms;
};
}
# TODO: a more Nixpkgs-tailoired test suite
|