blob: 050b971af94beb902c99ef1ce336cc593c5d4e63 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{ lib, fetchFromGitHub, stdenv, rustPlatform, coreutils, bash, installShellFiles, libiconv }:
rustPlatform.buildRustPackage rec {
pname = "just";
version = "1.0.1";
src = fetchFromGitHub {
owner = "casey";
repo = pname;
rev = version;
sha256 = "sha256-ssc6djhSk0xV4jdlTmehWX6UMBPAuebtYlzWRZ/32mM=";
};
cargoSha256 = "sha256-ynYK37nCfIiy1CHBEQ/vMHOAPY/pp/lF/tSl9MJD7fY=";
nativeBuildInputs = [ installShellFiles ];
buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
checkInputs = [ coreutils bash ];
preCheck = ''
# USER must not be empty
export USER=just-user
export USERNAME=just-user
export JUST_CHOOSER="${coreutils}/bin/cat"
# Prevent string.rs from being changed
cp tests/string.rs $TMPDIR/string.rs
sed -i src/justfile.rs \
-i tests/*.rs \
-e "s@/bin/echo@${coreutils}/bin/echo@g" \
-e "s@/usr/bin/env@${coreutils}/bin/env@g"
# Return unchanged string.rs
cp $TMPDIR/string.rs tests/string.rs
'';
checkFlags = [
"--skip=edit" # trying to run "vim" fails as there's no /usr/bin/env or which in the sandbox to find vim and the dependency is not easily patched
"--skip=run_shebang" # test case very rarely fails with "Text file busy"
"--skip=invoke_error_function" # wants JUST_CHOOSER to be fzf
];
postInstall = ''
installManPage man/just.1
installShellCompletion --cmd just \
--bash completions/just.bash \
--fish completions/just.fish \
--zsh completions/just.zsh
'';
meta = with lib; {
homepage = "https://github.com/casey/just";
changelog = "https://github.com/casey/just/blob/${version}/CHANGELOG.md";
description = "A handy way to save and run project-specific commands";
license = licenses.cc0;
maintainers = with maintainers; [ xrelkd jk ];
};
}
|