blob: 475b280c925a82dcda8a6ac56a051137959b5fb9 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
{ lib
, stdenv
, rustPlatform
, fetchFromGitHub
, help2man
, installShellFiles
, libiconv
, Security
, CoreServices
, nix-update-script
}:
let
isCross = stdenv.hostPlatform != stdenv.buildPlatform;
in
rustPlatform.buildRustPackage rec {
pname = "texlab";
version = "5.17.0";
src = fetchFromGitHub {
owner = "latex-lsp";
repo = "texlab";
rev = "refs/tags/v${version}";
hash = "sha256-4yMZxhq8Y3RFZHOlulG5hqj3bJSIYVycrtnmsbx+4bs=";
};
cargoHash = "sha256-/qT/mxKjVvyA6XAB0Oa6jpKss0YtIL6cvGwBHM8Bt4M=";
outputs = [ "out" ] ++ lib.optional (!isCross) "man";
nativeBuildInputs = [ installShellFiles ]
++ lib.optional (!isCross) help2man;
buildInputs = lib.optionals stdenv.isDarwin [
libiconv
Security
CoreServices
];
# When we cross compile we cannot run the output executable to
# generate the man page
postInstall = lib.optionalString (!isCross) ''
# TexLab builds man page separately in CI:
# https://github.com/latex-lsp/texlab/blob/v5.16.1/.github/workflows/publish.yml#L117-L121
help2man --no-info "$out/bin/texlab" > texlab.1
installManPage texlab.1
'';
passthru.updateScript = nix-update-script { };
meta = with lib; {
description = "Implementation of the Language Server Protocol for LaTeX";
homepage = "https://github.com/latex-lsp/texlab";
changelog = "https://github.com/latex-lsp/texlab/blob/v${version}/CHANGELOG.md";
license = licenses.mit;
maintainers = with maintainers; [ doronbehar kira-bruneau ];
platforms = platforms.all;
mainProgram = "texlab";
};
}
|