blob: ec5587273db29f65d5f06bac9d7fdd9f9eb62320 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
{ buildNpmPackage
, cctools
, darwin
, fetchFromGitHub
, lib
, nodePackages
, nodejs
, python3
, stdenv
}:
buildNpmPackage {
pname = "nodehun";
version = "3.0.2";
src = fetchFromGitHub {
owner = "Wulf";
repo = "nodehun";
rev = "03c9dcf1fcd965031a68553ccaf6487d1fe87f79";
hash = "sha256-MoY95lSIQK1K4aIlMdPm93YxJuez9HYx2zlUhHvDao0=";
};
patches = [
# fsevents is needed on Darwin, but its dependency "nan" in the upstream package-lock.json
# is too old for the Node 18.x in Nixpkgs.
# This patch is generated by checking out the upstream source and running
# npm update nan --lockfile-version 1
./update-nan.patch
];
npmDepsHash = "sha256-mV6rWNf2p2w4H0ESUT0/Ybtx9YEdvO5l2gCvlWFXK+U=";
buildInputs = lib.optionals stdenv.isDarwin [ darwin.apple_sdk.frameworks.CoreServices ];
nativeBuildInputs = [ nodePackages.node-gyp python3 ]
++ lib.optionals stdenv.isDarwin [ cctools ];
postInstall = ''
# Only keep the necessary parts of build/Release to reduce closure size
cd $out/lib/node_modules/nodehun
mv build build_old
mkdir build
cp -r build_old/Release build/
rm -rf build_old
rm -rf build/Release/.deps
# Remove a development script to eliminate runtime dependency on node
rm node_modules/node-addon-api/tools/conversion.js
'';
doInstallCheck = true;
nativeCheckInputs = [ nodejs ];
postInstallCheck = ''
# Smoke check: require() works
export NODE_PATH=$out/lib/node_modules
echo 'require("nodehun")' | node -
'';
disallowedReferences = [ nodejs ];
meta = with lib; {
description = "Hunspell binding for NodeJS that exposes as much of Hunspell as possible and also adds new features";
homepage = "https://github.com/Wulf/nodehun";
license = licenses.mit;
maintainers = [ maintainers.thomasjm ];
};
}
|
