blob: e08e2876c8fa0c35b2972d5be9e844bf04520a12 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
{ buildGoModule, fetchFromGitHub, lib }:
buildGoModule rec {
pname = "revive";
version = "1.3.9";
src = fetchFromGitHub {
owner = "mgechev";
repo = pname;
rev = "v${version}";
hash = "sha256-ZfZNqr7zeMrLjSS1h3ZbjiXNjX1UiqldtrEFth2Z4f0=";
# populate values that require us to use git. By doing this in postFetch we
# can delete .git afterwards and maintain better reproducibility of the src.
leaveDotGit = true;
postFetch = ''
date -u -d "@$(git -C $out log -1 --pretty=%ct)" "+%Y-%m-%d %H:%M UTC" > $out/DATE
git -C $out rev-parse HEAD > $out/COMMIT
rm -rf $out/.git
'';
};
vendorHash = "sha256-iIAKPCE06lhAf/4f4TRVO51RdlvuXNA7yMlGVPGrIeo=";
ldflags = [
"-s"
"-w"
"-X github.com/mgechev/revive/cli.version=${version}"
"-X github.com/mgechev/revive/cli.builtBy=nix"
];
# ldflags based on metadata from git and source
preBuild = ''
ldflags+=" -X github.com/mgechev/revive/cli.commit=$(cat COMMIT)"
ldflags+=" -X 'github.com/mgechev/revive/cli.date=$(cat DATE)'"
'';
# The following tests fail when built by nix:
#
# $ nix log /nix/store/build-revive.1.3.9.drv | grep FAIL
#
# --- FAIL: TestAll (0.01s)
# --- FAIL: TestTimeEqual (0.00s)
# --- FAIL: TestTimeNaming (0.00s)
# --- FAIL: TestUnhandledError (0.00s)
# --- FAIL: TestUnhandledErrorWithBlacklist (0.00s)
doCheck = false;
meta = with lib; {
description = "Fast, configurable, extensible, flexible, and beautiful linter for Go";
mainProgram = "revive";
homepage = "https://revive.run";
license = licenses.mit;
maintainers = with maintainers; [ maaslalani ];
};
}
|
