blob: e8f888680bad8eb4bce0b4dc5808f685b706cdad (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, darwin
, makeWrapper
, shared-mime-info
, boost
, wxGTK32
}:
stdenv.mkDerivation (finalAttrs: {
pname = "wxformbuilder";
version = "4.0.0";
src = fetchFromGitHub {
owner = "wxFormBuilder";
repo = "wxFormBuilder";
rev = "v${finalAttrs.version}";
fetchSubmodules = true;
leaveDotGit = true;
postFetch = ''
substituteInPlace $out/.git-properties \
--replace "\$Format:%h\$" "$(git -C $out rev-parse --short HEAD)" \
--replace "\$Format:%(describe)\$" "$(git -C $out rev-parse --short HEAD)"
rm -rf $out/.git
'';
hash = "sha256-Lqta+u9WVwUREsR7aH+2DJn0oM5QwlwRSBImuwNkmS4=";
};
postPatch = ''
substituteInPlace third_party/tinyxml2/cmake/tinyxml2.pc.in \
--replace '$'{exec_prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
sed -i '/fixup_bundle/d' cmake/macros.cmake
'';
nativeBuildInputs = [
cmake
] ++ lib.optionals stdenv.isDarwin [
darwin.sigtool
makeWrapper
] ++ lib.optionals stdenv.isLinux [
shared-mime-info
];
buildInputs = [
boost
wxGTK32
] ++ lib.optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.Cocoa
];
postInstall = lib.optionalString stdenv.isDarwin ''
mkdir -p $out/{Applications,bin}
mv $out/wxFormBuilder.app $out/Applications
makeWrapper $out/Applications/wxFormBuilder.app/Contents/MacOS/wxFormBuilder $out/bin/wxformbuilder
'';
meta = with lib; {
description = "RAD tool for wxWidgets GUI design";
homepage = "https://github.com/wxFormBuilder/wxFormBuilder";
license = licenses.gpl2Only;
mainProgram = "wxformbuilder";
maintainers = with maintainers; [ matthuszagh wegank ];
platforms = platforms.unix;
};
})
|