blob: a1b03a0a3b368e7c6a3c60fe35e72b599c72e47c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
{ lib, stdenv, fetchurl, nixosTests, jre_headless, makeWrapper, udev, version, url, sha1 }:
stdenv.mkDerivation {
pname = "minecraft-server";
inherit version;
src = fetchurl { inherit url sha1; };
preferLocalBuild = true;
nativeBuildInputs = [ makeWrapper ];
installPhase = ''
runHook preInstall
install -Dm644 $src $out/lib/minecraft/server.jar
makeWrapper ${lib.getExe jre_headless} $out/bin/minecraft-server \
--append-flags "-jar $out/lib/minecraft/server.jar nogui" \
--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ udev ]}
runHook postInstall
'';
dontUnpack = true;
passthru = {
tests = { inherit (nixosTests) minecraft-server; };
updateScript = ./update.py;
};
meta = with lib; {
description = "Minecraft Server";
homepage = "https://minecraft.net";
sourceProvenance = with sourceTypes; [ binaryBytecode ];
license = licenses.unfreeRedistributable;
platforms = platforms.unix;
maintainers = with maintainers; [ thoughtpolice tomberek costrouc joelkoen ];
};
}
|