blob: cfe594d518ed494ed1700186c5e6a5f0fb4277cf (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
{
lib,
crossLibcStdenv,
makeScopeWithSplicing',
generateSplicesForMkScope,
buildPackages,
}:
let
otherSplices = generateSplicesForMkScope "openbsd";
buildOpenbsd = otherSplices.selfBuildHost;
in
makeScopeWithSplicing' {
inherit otherSplices;
f = (
self:
lib.packagesFromDirectoryRecursive {
callPackage = self.callPackage;
directory = ./pkgs;
}
// {
version = "7.5";
stdenvLibcMinimal = crossLibcStdenv.override (old: {
cc = old.cc.override {
libc = self.libcMinimal;
noLibc = false;
bintools = old.cc.bintools.override {
libc = self.libcMinimal;
noLibc = false;
sharedLibraryLoader = null;
};
};
});
makeMinimal = buildPackages.netbsd.makeMinimal.override { inherit (self) make-rules; };
# The manual callPackages below should in principle be unnecessary, but are
# necessary. See note in ../netbsd/default.nix
include = self.callPackage ./pkgs/include/package.nix {
inherit (buildOpenbsd) makeMinimal;
inherit (buildPackages.netbsd) install rpcgen mtree;
};
csu = self.callPackage ./pkgs/csu.nix {
inherit (self) include;
inherit (buildOpenbsd) makeMinimal;
inherit (buildPackages.netbsd) install;
};
libcMinimal = self.callPackage ./pkgs/libcMinimal/package.nix {
inherit (self) csu include;
inherit (buildOpenbsd) makeMinimal;
inherit (buildPackages.netbsd)
install
gencat
tsort
rpcgen
;
};
librpcsvc = self.callPackage ./pkgs/librpcsvc.nix {
inherit (buildOpenbsd) openbsdSetupHook makeMinimal lorder;
inherit (buildPackages.netbsd)
install
tsort
statHook
rpcgen
;
};
libutil = self.callPackage ./pkgs/libutil.nix {
inherit (self) libcMinimal;
inherit (buildOpenbsd) openbsdSetupHook makeMinimal lorder;
inherit (buildPackages.netbsd) install tsort statHook;
};
lorder = self.callPackage ./pkgs/lorder.nix { inherit (buildPackages.netbsd) install; };
make-rules = self.callPackage ./pkgs/make-rules/package.nix { };
mkDerivation = self.callPackage ./pkgs/mkDerivation.nix {
inherit (buildPackages.netbsd) install tsort;
inherit (buildPackages.buildPackages) rsync;
};
}
);
}
|