blob: d14b6210f257d68dc3e192e3d9e147de0a56de34 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
{ lib, stdenv, fetchurl
, buildPackages, bison, flex, pkg-config
, db, iptables, elfutils, libmnl ,libbpf
, gitUpdater
}:
stdenv.mkDerivation rec {
pname = "iproute2";
version = "6.10.0";
src = fetchurl {
url = "mirror://kernel/linux/utils/net/${pname}/${pname}-${version}.tar.xz";
hash = "sha256-kaYvgnN7RJBaAPqAM2nER9VJ6RTpoqQBj911sdVOjc4=";
};
postPatch = ''
substituteInPlace Makefile \
--replace "CC := gcc" "CC ?= $CC"
'';
outputs = [ "out" "dev" ];
configureFlags = [
"--color" "auto"
];
makeFlags = [
"PREFIX=$(out)"
"SBINDIR=$(out)/sbin"
"DOCDIR=$(TMPDIR)/share/doc/${pname}" # Don't install docs
"HDRDIR=$(dev)/include/iproute2"
] ++ lib.optionals stdenv.hostPlatform.isStatic [
"SHARED_LIBS=n"
# all build .so plugins:
"TC_CONFIG_NO_XT=y"
] ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
"HOSTCC=$(CC_FOR_BUILD)"
];
buildFlags = [
"CONFDIR=/etc/iproute2"
];
installFlags = [
"CONFDIR=$(out)/etc/iproute2"
];
depsBuildBuild = [ buildPackages.stdenv.cc ]; # netem requires $HOSTCC
nativeBuildInputs = [ bison flex pkg-config ];
buildInputs = [ db iptables libmnl libbpf ]
# needed to uploaded bpf programs
++ lib.optionals (!stdenv.hostPlatform.isStatic) [ elfutils ];
enableParallelBuilding = true;
passthru.updateScript = gitUpdater {
# No nicer place to find latest release.
url = "https://git.kernel.org/pub/scm/network/iproute2/iproute2.git";
rev-prefix = "v";
};
meta = with lib; {
homepage = "https://wiki.linuxfoundation.org/networking/iproute2";
description = "Collection of utilities for controlling TCP/IP networking and traffic control in Linux";
platforms = platforms.linux;
license = licenses.gpl2Only;
maintainers = with maintainers; [ primeos eelco fpletz globin ];
};
}
|
