blob: b1d38c4adc3d4bf6c4f817982722c383d16575fd (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
{ stdenv
, lib
, fetchFromGitHub
, python3
, unstableGitUpdater
}:
stdenv.mkDerivation rec {
pname = "klipper";
version = "unstable-2023-02-03";
src = fetchFromGitHub {
owner = "KevinOConnor";
repo = "klipper";
rev = "5644481590a16ac5b3d8c20874f0477d5d51a963";
sha256 = "sha256-OGFVcUPw0sqTbJyrMvCxp8nER9/42ZRN4zIrpm/qh4E=";
};
sourceRoot = "source/klippy";
# NB: This is needed for the postBuild step
nativeBuildInputs = [ (python3.withPackages ( p: with p; [ cffi ] )) ];
buildInputs = [ (python3.withPackages (p: with p; [ cffi pyserial greenlet jinja2 markupsafe numpy ])) ];
# we need to run this to prebuild the chelper.
postBuild = ''
python ./chelper/__init__.py
'';
# Python 3 is already supported but shebangs aren't updated yet
postPatch = ''
for file in klippy.py console.py parsedump.py; do
substituteInPlace $file \
--replace '/usr/bin/env python2' '/usr/bin/env python'
done
'';
# NB: We don't move the main entry point into `/bin`, or even symlink it,
# because it uses relative paths to find necessary modules. We could wrap but
# this is used 99% of the time as a service, so it's not worth the effort.
installPhase = ''
runHook preInstall
mkdir -p $out/lib/klipper
cp -r ./* $out/lib/klipper
# Moonraker expects `config_examples` and `docs` to be available
# under `klipper_path`
cp -r $src/docs $out/lib/docs
cp -r $src/config $out/lib/config
chmod 755 $out/lib/klipper/klippy.py
runHook postInstall
'';
passthru.updateScript = unstableGitUpdater { url = meta.homepage; };
meta = with lib; {
description = "The Klipper 3D printer firmware";
homepage = "https://github.com/KevinOConnor/klipper";
maintainers = with maintainers; [ lovesegfault zhaofengli cab404 ];
platforms = platforms.linux;
license = licenses.gpl3Only;
};
}
|