pkgs/servers/mail/mailman/python.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

{ python3 }:

python3.override {
  packageOverrides = self: super: {
    # does not find tests
    alembic = super.alembic.overridePythonAttrs (oldAttrs:  {
      doCheck = false;
    });
    # Needed by mailman, see https://gitlab.com/mailman/mailman/-/issues/964
    sqlalchemy = super.sqlalchemy.overridePythonAttrs (oldAttrs: rec {
      version = "1.3.24";
      src = super.fetchPypi {
        inherit version;
        inherit (oldAttrs) pname;
        sha256 = "06bmxzssc66cblk1hamskyv5q3xf1nh1py3vi6dka4lkpxy7gfzb";
      };
      # does not find tests
      doCheck = false;
    });
    # Fixes `AssertionError: database connection isn't set to UTC`
    psycopg2 = super.psycopg2.overridePythonAttrs (a: (rec {
      version = "2.8.6";
      src = super.fetchPypi {
        inherit version;
        inherit (a) pname;
        sha256 = "fb23f6c71107c37fd667cb4ea363ddeb936b348bbd6449278eb92c189699f543";
      };
    }));
  };
}