blob: 6c1d22c8f7e95d4f34924eefe7afd363dd57ecfd (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
{ lib, python3, mautrix-telegram, fetchFromGitHub }:
let
python = python3.override {
packageOverrides = self: super: {
sqlalchemy = super.sqlalchemy.overridePythonAttrs (oldAttrs: rec {
version = "1.3.24";
src = oldAttrs.src.override {
inherit version;
sha256 = "ebbb777cbf9312359b897bf81ba00dae0f5cb69fba2a18265dcc18a6f5ef7519";
};
});
};
};
# officially supported database drivers
dbDrivers = with python.pkgs; [
psycopg2
# sqlite driver is already shipped with python by default
];
in python.pkgs.buildPythonPackage rec {
pname = "mautrix-telegram";
version = "0.9.0";
disabled = python.pythonOlder "3.7";
src = fetchFromGitHub {
owner = "tulir";
repo = pname;
rev = "v${version}";
sha256 = "1543ljjl3jg3ayid7ifi4bamqh4gq85pmlbs3m8i7phjbbm7g9dn";
};
patches = [ ./0001-Re-add-entrypoint.patch ./0002-Don-t-depend-on-pytest-runner.patch ];
postPatch = ''
sed -i -e '/alembic>/d' requirements.txt
'';
propagatedBuildInputs = with python.pkgs; [
Mako
aiohttp
mautrix
sqlalchemy
CommonMark
ruamel_yaml
python_magic
telethon
telethon-session-sqlalchemy
pillow
lxml
setuptools
] ++ dbDrivers;
# `alembic` (a database migration tool) is only needed for the initial setup,
# and not needed during the actual runtime. However `alembic` requires `mautrix-telegram`
# in its environment to create a database schema from all models.
#
# Hence we need to patch away `alembic` from `mautrix-telegram` and create an `alembic`
# which has `mautrix-telegram` in its environment.
passthru.alembic = python.pkgs.alembic.overrideAttrs (old: {
propagatedBuildInputs = old.propagatedBuildInputs ++ dbDrivers ++ [
mautrix-telegram
];
});
# Tests are broken and throw the following for every test:
# TypeError: 'Mock' object is not subscriptable
#
# The tests were touched the last time in 2019 and upstream CI doesn't even build
# those, so it's safe to assume that this part of the software is abandoned.
doCheck = false;
checkInputs = with python.pkgs; [
pytest
pytest-mock
pytest-asyncio
];
meta = with lib; {
homepage = "https://github.com/tulir/mautrix-telegram";
description = "A Matrix-Telegram hybrid puppeting/relaybot bridge";
license = licenses.agpl3Plus;
platforms = platforms.linux;
maintainers = with maintainers; [ nyanloutre ma27 ];
};
}
|