blob: 0d4a916db002dca514ce6dbbb4cf94c37b3b19eb (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
{ buildGoModule, fetchFromGitHub, lib }:
let
generic = { subPackages, pname, postInstall ? "", mainProgram }:
buildGoModule rec {
inherit pname;
version = "6.9.2";
shortRev = "3a1ac58"; # for internal version info
src = fetchFromGitHub {
owner = "sensu";
repo = "sensu-go";
rev = "v${version}";
sha256 = "sha256-Xd15fkoSmQXbkyEMsBvc8ewLvn+wlsZoclfDjarp1FQ=";
};
inherit subPackages postInstall;
vendorHash = "sha256-zrwTdMlDfG1RudOfV52qOP9NMU3/XYb5TND6xyglJ0I=";
doCheck = false;
ldflags = let
versionPkg = "github.com/sensu/sensu-go/version";
in [
"-X ${versionPkg}.Version=${version}"
"-X ${versionPkg}.BuildSHA=${shortRev}"
];
meta = {
inherit mainProgram;
homepage = "https://sensu.io";
description = "Open source monitoring tool for ephemeral infrastructure & distributed applications";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ thefloweringash ];
};
};
in
{
sensu-go-cli = generic {
pname = "sensu-go-cli";
subPackages = [ "cmd/sensuctl" ];
postInstall = ''
mkdir -p \
"''${!outputBin}/share/bash-completion/completions" \
"''${!outputBin}/share/zsh/site-functions"
''${!outputBin}/bin/sensuctl completion bash > ''${!outputBin}/share/bash-completion/completions/sensuctl
# https://github.com/sensu/sensu-go/issues/3132
(
echo "#compdef sensuctl"
''${!outputBin}/bin/sensuctl completion zsh
echo '_complete sensuctl 2>/dev/null'
) > ''${!outputBin}/share/zsh/site-functions/_sensuctl
'';
mainProgram = "sensuctl";
};
sensu-go-backend = generic {
pname = "sensu-go-backend";
subPackages = [ "cmd/sensu-backend" ];
mainProgram = "sensu-backend";
};
sensu-go-agent = generic {
pname = "sensu-go-agent";
subPackages = [ "cmd/sensu-agent" ];
mainProgram = "sensu-agent";
};
}
|
