blob: 0a3c0f00f913ed5fb7640cdda495be38b0bda58d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
{ lib
, rustPlatform
, fetchFromGitHub
, protobuf
, stdenv
, pkg-config
, openssl
, Security
}:
rustPlatform.buildRustPackage rec {
pname = "qdrant";
version = "1.0.2";
src = fetchFromGitHub {
owner = "qdrant";
repo = "qdrant";
rev = "refs/tags/v${version}";
sha256 = "sha256-AVglZr3J9fEWgE2g5UHt1j6YQud/viGp0IvuR9XRntE=";
};
cargoSha256 = "sha256-4hzixh1/nVIMRsBSoldmbtpcpBMmvxik3lV/h4FPOrk=";
prePatch = lib.optionalString stdenv.isAarch64 ''
substituteInPlace .cargo/config.toml \
--replace "[target.aarch64-unknown-linux-gnu]" "" \
--replace "linker = \"aarch64-linux-gnu-gcc\"" ""
'';
# Needed to get openssl-sys to use pkg-config.
OPENSSL_NO_VENDOR = 1;
buildInputs = [ openssl ] ++ lib.optionals stdenv.isDarwin [ Security ];
nativeBuildInputs = [ protobuf rustPlatform.bindgenHook pkg-config ];
NIX_CFLAGS_COMPILE = lib.optional stdenv.isDarwin "-faligned-allocation";
meta = with lib; {
description = "Vector Search Engine for the next generation of AI applications";
longDescription = ''
Expects a config file at config/config.yaml with content similar to
https://github.com/qdrant/qdrant/blob/master/config/config.yaml
'';
homepage = "https://github.com/qdrant/qdrant";
license = licenses.asl20;
maintainers = with maintainers; [ dit7ya ];
};
}
|